Question

请考虑这个简单的rebol2代码来说明我的问题：

REBOL []
a: make face [
    offset: 0x0
    color: yellow
    size: 20x20
]
b: make face [
    offset: 0x0
    color: red
    size: 60x60
    pane: reduce [
        make a [offset: 0x0]
        make a [offset: 10x10]
        make a [offset: 10x20]
    ]
]
view layout [
    box 200x200 white with [
        pane: reduce [
            make b [offset: 0x30] ;; one 'instance' of b
        ]
    ]
]

这里的要点是布局（或面）能够在其窗格块内显示一堆面，以便同一面的多个创建（在这种情况下为b）应该有可能。显示的代码运行良好，b唯一的实例（让我这样称呼它）显示为应该的样子。

但是现在假设我改变了代码，所以我有b的2个实例：

view  layout [
    box 200x200 white with [
        pane: reduce [
            make b [offset: 0x30]
            make b [offset: 0x10]
        ]
    ]
]

此时我收到错误

** Script Error: Face object reused (in more than one pane): none
** Where: view
** Near: show scr-face
if new [do-events]

从我在这里假设的消息中，b面孔以某种方式被重用并且正在弄清楚我想要实现的目标。我已经对此进行了大量研究，并且在某些时候我发现可以通过克隆（使用make）将面传递给pane来绕过它;这就是我以为我在做什么，但根本没有成功。

鉴于这种情况，我的问题是：我该如何解决这个问题？是rebol2可以提供这个＆＃34;面部实例化＆＃34;或者最好在rebol2之外尝试别的东西（也许是rebol3）？

非常感谢任何帮助。

Answer 1

正如已经指出的那样，问题是a被重用，而不是b！

布局函数使用名为init的字段来处理这样的事情。据我了解，init首先绑定到面部，然后在面部本身被实例化后（至少部分地）使用do调用。

在这种情况下，我将在布局中使用style命令（仍然部分使用面对象a）

view layout [
    style
        bb box 60x60
        with [
            append init [
                pane reduce [
                    make a [offset: 0x0]
                    make a [offset: 10x10]
                    make a [offset: 10x20]
               ]
            ]
        ]
    panel 200x200 white [
        at 30x0 bb
        at 0x0  bb
    ]
]

另一种选择，与你的相似之处是：

b: make face [
    offset: 0x0
    color: red
    size: 60x60
    init: [
        pane: reduce [
            make a [offset: 0x0]
            make a [offset: 10x10]
            make a [offset: 10x20]
        ]
    ]
]
view layout [
    box 200x200
    with [
        append init [
            pane: reduce [
                make b [ offset: 0x0 do init ]
                make b [ offset: 0x60 do init ]
            ]
        ]
    ]
 ]

请注意，在这种情况下，在make子句中手动调用init。我不确定为什么需要它。最后，一切都可以用风格优雅地解决

view layout [
    style a box yellow 20x20
    style b panel red 60x60 [
        at 0x0 a   ; we can in this style use the just defined a style
        at 10x10 a
        at 10x20 a
    ]
    at 0x0 b
    at 0x60 b
]

Answer 2

我在评论中说过，我会回来分享我的发现，我觉得我有一些有趣的东西。正如@ endo64所指出的那样，迭代的面孔很棘手，也许最不适合我在第一次提出这个问题时打算做的事情 - 实现一种简单/直接的方式来通过面板实例化对象。

我提出了代码bellow，它实现了一种 instantiator 。它的灵感部分来自@ endo64的 face-maker 方法以及对迭代面的一些修补。此实例化器具有核心限制，该核心限制不接受传递给要在同一窗格中创建的构造函数的多种类型的对象。

无论如何，我发现这是一个有趣的练习，我想在这里发布，以防它对某人有用。

我使用问题中的相同代码，现在解决/避免在主布局窗格中创建多个b对象的限制。 a和b现在拥有一个instantiator对象，该对象接收要在其窗格内创建的对象以及应放置对象的位置块（对偏移）。

a: make face [
    offset: 0x0
    color: yellow
    size: 30x20
]

b: make face [
    offset: 0x0
    color: red
    size: 100x100
    inst_b: _instantiator/new reduce a [10x10 10x70 80x80 30x30] ; instantiator here  
    pane: get in inst_b 'pane_function
]

instantiator 代码是：

_instantiator: make object! [
    _obj: copy []
    _offsets: copy []

    new: func [
        obj [object!] "object to create inside pane"
        offs [block!] "instances offsets"
    ][
        make self [
            _obj: obj
            _offsets: offs
        ]
    ]   
    pane_function: func [face index] [
        if integer? index [
            if index <= length? _offsets [
                _obj/offset: to-pair reduce [_offsets/:index/x _offsets/:index/y]
                _obj
            ]
        ]
    ]   
]

主要布局代码为：

_inst: _instantiator/new reduce b [0x0 50x50 130x130] ;;3 b objects are created in the positions indicated in the pairs block
_lo: layout [
    mybox: box 500x500 white with [
        offset: 0x0     
        pane: get in _inst 'pane_function
    ]   
]
view center-face _lo

VID布局窗格支持多个面部创建[rebol2]

2 个答案: