Question

在下面给出的Fortran代码中，我将所有涉及PI计算的数字作为双精度，但PI I得到的值只是一个实数，最后有大量的零或9。如何使程序以双精度给出PI？我正在使用gfortran编译器。

  !This program determines the value of pi using Monte-Carlo algorithm.
  program findpi
  implicit none
  double precision :: x,y,radius,truepi,cnt
  double precision,allocatable,dimension(:) :: pi,errpi
  integer :: seedsize,i,t,iter,j,k,n
  integer,allocatable,dimension(:) :: seed

  !Determining the true value of pi to compare with the calculated value
  truepi=4.D0*ATAN(1.D0)

  call random_seed(size=seedsize)
  allocate(seed(seedsize))
  do i=1,seedsize
     call system_clock(t) !Using system clock to randomise the seed to 
                          !random number generator
     seed(i)=t
  enddo
  call random_seed(put=seed)

  n=2000         !Number of times value of pi is determined
  allocate(pi(n),errpi(n))
  do j=1,n
     iter=n*100  !Number of random points
     cnt=0.D0
     do i=1,iter
        call random_number(x)
        call random_number(y)
        radius=sqrt(x*x + y*y)
        if (radius < 1) then
           cnt = cnt+1.D0
        endif
     enddo
     pi(j)=(4.D0*cnt)/dble(iter)
     print*, j,pi(j)
  enddo

  open(10,file="pi.dat",status="replace")
  write(10,"(F15.8,I10)") (pi(k),k,k=1,n)

  call system("gnuplot --persist piplot.gnuplot")

end program findpi

Answer 1

您的计算是双精度的，但我看到两个问题：

第一个是系统错误......你通过

pi(j)=(4.D0*cnt)/dble(iter)

iter最多为2000 * 100，因此1/iter至少为5e-6，因此您无法解决任何查找内容; - ）

第二个问题是您的IO例程以单精度打印结果！这条线

write(10,"(F15.8,I10)") (pi(k),k,k=1,n)

更具体地说，需要调整格式说明符"(F15.8,I10)"。目前它告诉编译器总共使用15个字符来打印数字，小数点后面有8位数字。作为第一项措施，您可以使用*：

write(10,*) (pi(k),k,k=1,n)

这总共使用了22个字符，所有15位数都是双精度：

write(10,"(F22.15,I10)") (pi(k),k,k=1,n)

如何在fortran中以双精度进行所有计算？

1 个答案: