Question

通常，在Delphi中，可以使用'array of const'方法声明一个带有可变数量参数的函数。但是，为了与用C编写的代码兼容，有一个未知的'varargs'指令可以添加到函数声明中（我在阅读Rudy的优秀“Pitfalls of convering”文档时学到了这一点。）

例如，可以在C中使用函数，声明如下：

void printf(const char *fmt, ...)

在Delphi中，这将成为：

procedure printf(const fmt: PChar); varargs;

我的问题是：在实现使用'varargs'指令定义的方法时，如何获取堆栈的内容？

我希望有一些工具存在，比如va_start（），va_arg（）和va_end（）函数的Dephi翻译，但我无法在任何地方找到它。

请帮忙！

PS：请不要讨论'为什么'或'数组的const'替代方案 - 我需要这个为Xbox游戏中的函数编写类似C的补丁（参见Delphi Xbox模拟器项目'Dxbx '在sourceforge上了解详情。）

Answer 1

好的，我在你的问题中看到澄清意味着你需要在Delphi中实现C导入。在这种情况下，您需要自己实现varargs。

所需的基本知识是x86上的C调用约定：堆栈向下增长，C从右向左推送参数。因此，在最后声明的参数的大小递增之后，指向最后声明的参数的指针将指向尾参数列表。从那时起，只需要读出参数并将指针递增适当的大小以深入到堆栈中即可。 32位模式下的x86堆栈通常是4字节对齐，这也意味着字节和字传递为32位整数。

无论如何，这是演示程序中的帮助记录，显示了如何读取数据。请注意，Delphi似乎以非常奇怪的方式传递扩展类型;但是，您可能不必担心这一点，因为10字节浮点数通常不会在C中广泛使用，甚至在最新的MS C，IIRC中也没有实现。

{$apptype console}

type  
  TArgPtr = record
  private
    FArgPtr: PByte;
    class function Align(Ptr: Pointer; Align: Integer): Pointer; static;
  public
    constructor Create(LastArg: Pointer; Size: Integer);
    // Read bytes, signed words etc. using Int32
    // Make an unsigned version if necessary.
    function ReadInt32: Integer;
    // Exact floating-point semantics depend on C compiler.
    // Delphi compiler passes Extended as 10-byte float; most C
    // compilers pass all floating-point values as 8-byte floats.
    function ReadDouble: Double;
    function ReadExtended: Extended;
    function ReadPChar: PChar;
    procedure ReadArg(var Arg; Size: Integer);
  end;

constructor TArgPtr.Create(LastArg: Pointer; Size: Integer);
begin
  FArgPtr := LastArg;
  // 32-bit x86 stack is generally 4-byte aligned
  FArgPtr := Align(FArgPtr + Size, 4);
end;

class function TArgPtr.Align(Ptr: Pointer; Align: Integer): Pointer;
begin
  Integer(Result) := (Integer(Ptr) + Align - 1) and not (Align - 1);
end;

function TArgPtr.ReadInt32: Integer;
begin
  ReadArg(Result, SizeOf(Integer));
end;

function TArgPtr.ReadDouble: Double;
begin
  ReadArg(Result, SizeOf(Double));
end;

function TArgPtr.ReadExtended: Extended;
begin
  ReadArg(Result, SizeOf(Extended));
end;

function TArgPtr.ReadPChar: PChar;
begin
  ReadArg(Result, SizeOf(PChar));
end;

procedure TArgPtr.ReadArg(var Arg; Size: Integer);
begin
  Move(FArgPtr^, Arg, Size);
  FArgPtr := Align(FArgPtr + Size, 4);
end;

procedure Dump(const types: string); cdecl;
var
  ap: TArgPtr;
  cp: PChar;
begin
  cp := PChar(types);
  ap := TArgPtr.Create(@types, SizeOf(string));
  while True do
  begin
    case cp^ of
      #0: 
      begin
        Writeln;
        Exit;
      end;

      'i': Write(ap.ReadInt32, ' ');
      'd': Write(ap.ReadDouble, ' ');
      'e': Write(ap.ReadExtended, ' ');
      's': Write(ap.ReadPChar, ' ');
    else
      Writeln('Unknown format');
      Exit;
    end;
    Inc(cp);
  end;
end;

type
  PDump = procedure(const types: string) cdecl varargs;
var
  MyDump: PDump;

function AsDouble(e: Extended): Double;
begin
  Result := e;
end;

function AsSingle(e: Extended): Single;
begin
  Result := e;
end;

procedure Go;
begin
  MyDump := @Dump;

  MyDump('iii', 10, 20, 30);
  MyDump('sss', 'foo', 'bar', 'baz');

  // Looks like Delphi passes Extended in byte-aligned
  // stack offset, very strange; thus this doesn't work.
  MyDump('e', 2.0);
  // These two are more reliable.
  MyDump('d', AsDouble(2));
  // Singles passed as 8-byte floats.
  MyDump('d', AsSingle(2));
end;

begin
  Go;
end.

Answer 2

我找到this（来自guy我们知道:)）

要正确地编写这些东西，你需要使用内置的Delphi BASM 汇编程序，并在asm中编码调用序列。希望你有一个好的你需要做什么的想法。也许.basm小组中的帖子会有用你卡住了

Answer 3

Delphi不允许您实现varargs例程。它只适用于导入使用它的外部cdecl函数。

由于varargs基于cdecl调用约定，你基本上需要在Delphi中使用汇编和/或各种指针操作重新实现它。

带有'varargs'的函数如何检索堆栈的内容？

3 个答案: