我正在尝试使用包含以下内容的stat.dat文件制作图表：
----system---- ----total-cpu-usage---- ------memory-usage----- -net/total-
time |usr sys idl wai hiq siq| used buff cach free| recv send
22-04 16:44:48| 0 0 100 0 0 0| 162M 57.1M 360M 3376M| 0 0
22-04 16:44:58| 0 0 100 0 0 0| 161M 57.1M 360M 3377M| 180B 317B
我有gnu.sh包含：
#!/usr/bin/gnuplot
set terminal png
set output "top.png"
set title "CPU usage"
set xlabel "time"
set ylabel "percentage"
set xdata time
set timefmt "%d-%m %H:%M:%S"
set format x "%H:%M"
plot "stat.dat" using 1:3 title "system" with lines, \
"stat.dat" using 1:2 title "user" with lines, \
"stat.dat" using 1:4 title "idle" with lines
当我运行gnu文件时，我收到此错误：
Could not find/open font when opening font "/usr/share/fonts/truetype/ttf-liberation/LiberationSans-Regular.ttf", using internal non-scalable font
----system---- ----total-cpu-usage---- ------memory-usage----- -net/total...
stat.dat:1:"./gnu.sh", line 12: illegal day of month
是否有人熟悉此错误以及任何有用的解决方案？
答案 0 :(得分：0)
解析数据文件的第一行时，gnuplot会遇到一个月的非法日期。
在解析之前，您必须以某种方式跳过数据文件的前两行。使用版本5.0或4.6.6，您可以使用新的skip选项来实现此目的。这会跳过数据文件开头的许多行而不解析它们（而不是every，这可能会在解析后跳过多行，这仍会产生错误） ：
set xdata time
set timefmt "%d-%m %H:%M:%S"
set format x "%H:%M"
set style data lines
set border back
plot "stat.dat" using 1:4 skip 2 lw 3 title "system", \
"" using 1:3 skip 2 lw 3 title "user", \
"" using 1:5 skip 2 lw 3 title "idle"
另请注意，您的列计数错误。日期包含一个空格，因此当您引用以下值时，它会计入两列。
或者，如果您没有版本5.0或4.6.6，则可以使用tail之类的外部工具跳过前两行：
set xdata time
set timefmt "%d-%m %H:%M:%S"
set format x "%H:%M"
set style data lines
set border back
plot "< tail -n +3 stat.dat" using 1:4 lw 3 title "system", \
"" using 1:3 lw 3 title "user", \
"" using 1:5 lw 3 title "idle"