Question

我使用xslt编辑多个文件。我的输入文件是我的设置文件，它看起来像这样：

<root>
  <file>
    <folderin>/var/in/</folderin>
    <in>10</in>
    <folderout>/var/out</folderout>
    <out>20</out>
    <name>First file</name>
  </file>
</root>

示例文件：

<root>
  <element1 id1="10">
    ...
  </element1>
  <element2 id2="10" attribute="xyz">
    ...
  </element2>
</root>

我的xslt文件：

<?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" indent="yes" encoding="utf-8"/>
        <xsl:template name="CopyXml" match="/*">
        <xsl:for-each select="file">
            <xsl:variable name="inputfile" select="concat(folderin, in, '.xml')"/>
            <xsl:variable name="outputfile" select="concat(folderout, out, '.xml')"/>

            <xsl:result-document method="xml" href="{$outputfile}">
                    <xsl:copy-of select="document($inputfile)/*"/>
            </xsl:result-document>
            </xsl:for-each>
        </xsl:template>

    </xsl:stylesheet>

在/ var / in /中有几百个文件，我只想编辑少量文件（在本例中/var/in/10.xml，带有退出文件/var/out/20.xml）。在新文件中，我想将id1和id2属性值更改为我的＆＃34; out＆＃34; param

我已经设法使用我的xslt复制了具有足够名称的特定文件，但是我在应用任何模板时遇到问题，因此我可以更改这些文件。我尝试过使用apply-templates但是我不能让它将这些模板应用到$ outputFile，它要么没有做任何事情，要么附加$ outputFile和设置文件中的副本; /有没有人知道如何做到了吗？

编辑：此示例文件的输出：

<root>
  <element1 id1="20">
    ...
  </element1>
  <element2 id2="20" attribute="xyz">
    ...
  </element2>
</root>

Answer 1

目前你的样式表有：

        <xsl:result-document method="xml" href="{$outputfile}">
                <xsl:copy-of select="document($inputfile)/*"/>
        </xsl:result-document>

因此，您正在创建一个输出文件，将包含输入文件的副本。

要应用某些修改，您必须将模板应用于输入文件，因此您需要：

        <xsl:result-document method="xml" href="{$outputfile}">
                <!-- further process the input file -->
                <xsl:apply-templates select="document($inputfile)/*"/>
        </xsl:result-document>

当然，样式表必须包含处理输入文件内容的模板，复制和修改相关部分。

您可以尝试逐步解决问题：

首先，定义一个样式表，其中包含将单个输入文件转换为单个输出文件的规则
一旦这些模板执行了您需要的操作，请将它们复制到应用于设置文件的样式表中

此样式表应该满足您的需求：

XSLT 2.0：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" indent="yes" encoding="utf-8"/>

    <!-- template to process the settings file -->
    <xsl:template match="/">
        <xsl:for-each select="root/file">
            <xsl:variable name="inputfile" select="concat(folderin, in, '.xml')"/>
            <xsl:variable name="outputfile" select="concat(folderout, out, '.xml')"/>

            <xsl:result-document method="xml" href="{$outputfile}">
                <xsl:apply-templates select="document($inputfile)/*" mode="processFiles">
                    <xsl:with-param name="outputValue" select="out" tunnel="yes"/>
                </xsl:apply-templates>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>

    <!-- template to process the input files -->
    <!-- identity transformation -->
    <xsl:template match="* | @* | text()" mode="processFiles">
        <xsl:copy>
            <xsl:apply-templates select="* | @* | text()" mode="#current"/>
        </xsl:copy>
    </xsl:template>
    <!-- update parameters -->
    <xsl:template match="@id1 | @id2" mode="processFiles">
        <xsl:param name="outputValue" tunnel="yes"/>
        <xsl:attribute name="{name()}">
            <xsl:value-of select="$outputValue"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

值得注意的要点：

你不能只复制输入文件，你必须应用模板才能更改它的某些部分
在将模板应用于外部文件时，会传递一个名为outputValue的参数;使用tunnel parameter可以免除每次调用xsl:apply-templates
我使用mode="processFile"的模板来处理外部文件的内容;在这种简单的情况下并不是绝对必要的，但是在使用更大的样式表时，这是一个小小的＆＃34;技巧＆＃34;这有助于避免设置文件的模板与外部文件的模板之间的优先级冲突
- 身份模板只复制元素，属性和文本节点
- 属性id1和id2的特定模板使用tunnel参数将现有值替换为所需的值

带设置的XSLT输入文件 - 更改多个输出文件

1 个答案: