如何在SAS SGPLOT图形中旋转x轴标签，使它们垂直（与x轴成90度）

Question

是否可以在SAS SGPLOT中旋转x轴标签，使它们垂直（与x轴成90度）？ fitpolicy选项旋转45度，但这不是我需要的。

SAS代码：

ods pdf style = custom file='';
proc sgplot data = filename;
series x = date y = unemployment_rate_15_24 / lineattrs = (color = CX963634 thickness = 2 pattern=solid);
series x = date y = unemployment_rate_15_ / lineattrs = (color = CX538DD5 thickness = 2 pattern=solid);
xaxis type=time fitpolicy=rotatethin notimesplit interval=year offsetmax=0 label = ' ' values = ("28FEB1995"d to "28FEB2015"d by year);
yaxis label = ' ' values = (0 to 18 by 2);
x2axis display=(nolabel novalues);
keylegend / location = inside position = topright;
label unemployment_rate_15_24 = "Youth (15-24 years) unemployment rate";
label unemployment_rate_15_ = "Overall (15+ years) unemployment rate";
run;
ods pdf close;

我也试过在SAS中使用图形模板语言。这是用GTL编写的等价代码：

proc template;
define statgraph mysgplot;
begingraph;
layout overlay /
cycleattrs=true 
xaxisopts=(label=" " offsetmax=0 type=time timeopts=(tickvaluelist=(12842 13207 13573 13938 14303 14668 15034 15399 15764 16129 16495 16860 17225 17590 17956 18321 18686 19051 19417 19782 20147) viewmin=12842 viewmax=20147 tickvaluefitpolicy=rotatethin splittickvalue=false interval=year)) 
yaxisopts=(label=" " type=linear linearopts=(tickvaluelist=(0 2 4 6 8 10 12 14 16 18) viewmin=0 viewmax=18 )) 
x2axisopts=(display=(ticks line) type=auto);
seriesplot x='date'n y='unemployment_rate_15_24'n / primary=true lineattrs=( color=cx963634 pattern=1 thickness=2) legendlabel="Youth (15-24 years) unemployment rate" NAME="SERIES";
seriesplot x='date'n y='unemployment_rate_15_'n / lineattrs=( color=cx538dd5 pattern=1 thickness=2) legendlabel="Overall (15+ years) unemployment rate" NAME="SERIES1";
discretelegend "SERIES" "SERIES1" / location=inside halign=right valign=top;
endlayout;
endgraph;
end;
run;

proc sgrender data = filename template=mysgplot;
run;

Answer 1

我不相信在不使用注释的情况下可以在SGPLOT中这样做。他们使用注释here进行了很好的代码处理。

使用GTL，在9.4中他们引入TICKVALUEROTATION，需要与TICKVALUEFITPOLICY=ROTATE|ROTATEALWAYS和SPLITTICKVALUE=FALSE一起使用。见：

data testdata;
  call streaminit(7);
  do timevar = 12900 to 16900 by 500;
    age=10+rand('Normal',5,2);
    output;
  end;
  format timevar date9.;
run;

proc template;
define statgraph mysgplot;
begingraph;
layout overlay /
cycleattrs=true 
xaxisopts=(label=" " offsetmax=0 type=time 
    timeopts=(tickvaluerotation=VERTICAL TICKVALUEFITPOLICY=rotatealways splittickvalue=false) )
yaxisopts=(label=" " type=linear linearopts=(tickvaluelist=(0 2 4 6 8 10 12 14 16 18) viewmin=0 viewmax=18 )) 
x2axisopts=(display=(ticks line) type=auto);
seriesplot x=timevar y=age
    / lineattrs=( color=cx538dd5 pattern=1 thickness=2) legendlabel="Overall (15+ years) unemployment rate" NAME="SERIES1";
discretelegend "SERIES" "SERIES1" / location=inside halign=right valign=top;
endlayout;
endgraph;
end;
run;

proc sgrender data = testdata template=mysgplot;
run;

我略微简化你的轴以确保它正常工作，但我认为你的大多数轴声明都没问题。

在9.3或更早版本中，我认为您已经停留了注释或45度。或者看看你是否可以说服SCATTERPLOT画出轴外。或者也许使用SERIESPLOT和SCATTERPLOT绘制自己的轴，但这似乎有点过头了。

以上代码如下所示：

Answer 2

从SAS 9.4 TS1M3开始，您只需要一行简单的代码：

XAXIS VALUESROTATE=VERTICAL;

请参阅：http://support.sas.com/kb/48/432.html