在简单语法的输入上没有可行的替代方案

Question

我正在尝试使用ANTLR 4为简单的DSL创建一个解析器。我从我的测试和ANTLRWorks中得到“输入中没有可行的替代方案”。

语法：

grammar Test;
process: action ('|' action)* ;
action: (filter) | (transform) | (log);
transform: 'transform' '(' ( ('name' '=' transformName)|('regex' '=' regex)) ')' ;
transformName: NAME;
filter: 'filter' '(' ( ('name' '=' filterName)|('regex' '=' regex)) ')' ;
filterName: NAME;
regex: QUOTEDSTRING;
log: 'log' ('(' 'name' '=' logName (',' 'level' '=' logLevel)? ')')? ;
logName: NAME;
logLevel: NAME;
NAME : [a-zA-Z][a-zA-Z0-9_.]* ;
STRING : (~["])+ ;
QUOTEDSTRING: '"' STRING '"';
WS :  [ \t\r\n\u000C]+ -> skip ;

输入：

log (name=mylog,level=debug)

感谢任何帮助！

Answer 1

我认为您正在混合ANTLR4语法和ANTLR3语法（由ANTLRWorks支持）

尝试这样的事情

grammar Test;
eval    :process EOF;
process :action ('|' action)*;
action  :(filter) | (transform) | (log);
transform   :'transform' '(' ( ('name' '=' transformName)|('regex' '=' regex)) ')' ;
transformName   :NAME;
filter  :'filter' '(' ( ('name' '=' filterName)|('regex' '=' regex)) ')' ;
filterName  :NAME;
regex   :QUOTEDSTRING;
log :'log' ('(' 'name' '=' logName (',' 'level' '=' logLevel)? ')')? ;
logName :NAME;
logLevel:NAME;
WS  
    :   (
             ' '
        |    '\r'
        |    '\t'
        |    '\u000C'
        |    '\n'
        ) 
            {
                skip();
            }          
    ;
QUOTEDSTRING    :'"' NAME '"';
NAME    :('a'..'z'|'A'..'Z'|'_') ('a'..'z'|'A'..'Z'|'0'..'9'|'_')*;

似乎以这种方式工作

Answer 2

你的词法分析器代币不是分离的：

NAME : [a-zA-Z][a-zA-Z0-9_.]* ;
STRING : (~["])+ ;
QUOTEDSTRING: '"' STRING '"';
WS :  [ \t\r\n\u000C]+ -> skip ;

ANTLR首先在输入上处理这些规则。令牌是由这些规则中的任何一个匹配的最长序列。由于STRING几乎包含所有内容（双引号除外）：

log (name=mylog,level=debug)与STRING匹配，因为它匹配字符序列，空格，括号和相等的运算符。没有其他令牌类型可以获得如此长的匹配，因此首选STRING。

要解决此问题，请将您的词法规则分开：

NAME : [a-zA-Z][a-zA-Z0-9_.]* ;
QUOTEDSTRING: '"' (~["])+? '"';
WS :  [ \t\r\n\u000C]+ -> skip ;

QUOTEDSTRING仅匹配以双引号开头和结尾的长序列。您的行不会包含任何字符串。