Question

很抱歉，如果与我有同样的问题。

在Delphi中，我的功能如下：

function TModuleDatabase.LoadCountryList():TDictionary<integer, String>;
var
  UQ: TUniQuery;
  UC: TUniConnection;
  CountryList: TDictionary<integer, String>;
begin
  CountryList := TDictionary<integer, String>.Create;
  UC := UniConnection2;
  UQ := TUniQuery.Create(nil);
  try
    UQ.Connection := UC;
    try
      UQ.SQL.Clear;
      UQ.SQL.Add('SELECT ID,NAME FROM COUNTRY ORDER BY NAME ASC');
      UQ.Open;
      while not UQ.Eof do
      begin
        CountryList.Add(UQ.Fields.FieldByName('ID').AsInteger,UQ.Fields.FieldByName('NAME').AsString);
        UQ.Next;
      end;
      Result := CountryList;
    except
      on E:Exception do
        ModuleMsgDialog.WarningMsg(E.Message);
    end;
  finally
    UQ.Close;
    UQ.Free;
    CountryList.Free;
  end;
end;

我将该函数与其他DataModule分开，以使我不会在每个表单中每次重复此函数。但是当我从一个表单中调用这个函数时：

procedure TCompanyDetailsForm.FormCreate(Sender: TObject);
var
  i: Integer;
  sItem: String;
  CountryList: TDictionary<integer, String>;
begin
  PageControl1.ActivePage := AddressTab;

  CountryList := ModuleDatabase.LoadCountryList();
  for i in CountryList.Keys do
  begin
    LocationCbbx.Items.AddObject(CountryList.Items[i],TObject(i));
  end;
end;

问题出在 CountryList.Free; 。字典中的所有项目在使用前已经释放。如果我不自由，就会造成内存泄漏。

如何在免费之前传输数据的最佳方式。或者如何在通话后以其他形式或单位释放价值。

感谢您的帮助。

Answer 1

您有两个主要选择。

选项1 - 调用者提供实例化对象

在这里，您可以让来电者终身负责。调用者传入一个实例化对象，被调用者填充它。

procedure PopulateCountryDict(Countries: TDictionary<Integer, string>);
begin
  // populate Countries here
end;

选项2 - 调用方返回一个新实例化的对象，该对象也已填充

这是可行的，但是一旦被调用者返回，调用者必须承担生命周期的责任。它看起来像这样：

function CreateAndPopulateCountryDict: TDictionary<Integer, string>;
begin
  Result := TDictionary<Integer, string>.Create;
  try
    // populate Result here
  except
    Result.Free; // until this function returns, we are responsible for lifetime
    raise;
  end;
end;

调用代码如下所示：

var
  Countries: TDictionary<Integer, string>
....
Countries := CreateAndPopulateCountryDict;
try
  // do stuff with Countries
finally
  Countries.Free;
end;

Answer 2

作为David回答的扩展，还有另一个使用回调的选项

procedure LoadCountryList( ACallback : TProc<TDictionary<integer,string>> );
var
  LCountryList : TDictionary<integer,string>;
begin
  // create the instance
  LCountryList := TDictionary<integer,string>.Create;
  try
    // fill the dictionary

    // execute the callback
    ACallback( LCountryList );
  finally
    // free the instance
    LCountryList.Free;
  end;
end;

然后在您的代码中使用它

procedure TCompanyDetailsForm.FormCreate(Sender: TObject);
begin
  PageControl1.ActivePage := AddressTab;

  LoadCountryList( 
    procedure ( CountryList : TDictionary<integer,string> ) 
    var
      i: Integer;
    begin
      for i in CountryList.Keys do
      begin
        LocationCbbx.Items.AddObject(CountryList.Items[i],TObject(i));
      end;
    end );
end;

Answer 3

您应该在Form Create方法中创建字典，并销毁或清除您需要的位置。不在LoadCountryList函数中。

delphi在释放对象时会失去价值

3 个答案: