Question

我正在努力将我的一些Clojure代码移植到OCaml，我遇到了以下问题：

let rotate ll =
    let cons x y = x :: y in
    let init = List.map (fun _ -> []) (List.hd ll) in
    let rres = List.fold_right (List.map2 cons) ll init in
    List.rev rres;;

let rec spiral_print matrix acc =
    match matrix with
    | [] -> acc
    | head :: tail -> spiral_print (rotate tail)  (acc @ head);;

不幸的是，这会产生以下结果：

utop # spiral_print [[1; 2; 3]; [8; 9; 4]; [7; 6; 5]] [];;
Exception: (Failure hd).

我想调试为什么会发生这种情况，但是当我打开跟踪时，这就是我所得到的：

#trace spiral_print;;
spiral_print [[1; 2; 3]; [8; 9; 4]; [7; 6; 5]] [];;
spiral_print <-- [[<poly>; <poly>; <poly>]; [<poly>; <poly>; <poly>]; [<poly>; <poly>; <poly>]]
spiral_print --> <fun>
spiral_print* <-- []
spiral_print <-- [[<poly>; <poly>]; [<poly>; <poly>]; [<poly>; <poly>]]
spiral_print --> <fun>
spiral_print* <-- [<poly>; <poly>; <poly>]
spiral_print <-- [[<poly>; <poly>]; [<poly>; <poly>]]
spiral_print --> <fun>
spiral_print* <-- [<poly>; <poly>; <poly>; <poly>; <poly>]
spiral_print <-- [[<poly>]; [<poly>]]
spiral_print --> <fun>
spiral_print* <-- [<poly>; <poly>; <poly>; <poly>; <poly>; <poly>; <poly>]
spiral_print <-- [[<poly>]]
spiral_print --> <fun>
spiral_print* <-- [<poly>; <poly>; <poly>; <poly>; <poly>; <poly>; <poly>; <poly>]
spiral_print* raises (Failure hd)
spiral_print* raises (Failure hd)
spiral_print* raises (Failure hd)
spiral_print* raises (Failure hd)
spiral_print* raises (Failure hd)
Exception: (Failure hd).

有没有办法以某种方式检查各个函数执行的内部状态以捕获错误？

我会使用其他语言的印刷品或漂亮的印刷品。

Answer 1

ocamldebug以及toplevel将拒绝打印多态容器的元素，除非您约束类型：

let int_spiral_print : int list list -> int list -> int list = spiral_print;;
val int_spiral_print : int list list -> int list -> int list = <fun>
# #trace int_spiral_print;;
int_spiral_print is now traced.
# int_spiral_print [[1; 2; 3]; [8; 9; 4]; [7; 6; 5]] [];;
int_spiral_print <-- [[1; 2; 3]; [8; 9; 4]; [7; 6; 5]]
int_spiral_print --> <fun>
...

但是这里有正常的回溯会更有成效。要获得它，请将您的代码放入文件中，例如

$ cat spiral_print.ml

let rotate ll =
  let cons x y = x :: y in
  let init = List.map (fun _ -> []) (List.hd ll) in
  let rres = List.fold_right (List.map2 cons) ll init in
  List.rev rres

let rec spiral_print matrix acc =
  match matrix with
  | [] -> acc
  | head :: tail -> spiral_print (rotate tail)  (acc @ head)

let _ =
  Printexc.record_backtrace true;
  spiral_print [[1; 2; 3]; [8; 9; 4]; [7; 6; 5]] []

请注意，我添加了Printexc.record_backtrace true以启用通常禁用的回溯录制。您也可以使用环境变量OCAMLRUNPARAM=b启用它。然后你可以编译并运行你的程序，以获得一个很好的回溯：

ocamlbuild spiral_print.d.byte --
Fatal error: exception Failure("hd")
Raised at file "pervasives.ml", line 30, characters 22-33
Called from file "spiral_print.ml", line 3, characters 36-48
Called from file "spiral_print.ml", line 10, characters 33-46
Called from file "spiral_print.ml", line 14, characters 2-51

正确的文本编辑器（即emacs）甚至会为您突出显示异常来源为(List.hd ll)。

Answer 2

我写了旋转代码： - ）

如果将空白列表传递给该函数，该函数将失败。我认为那是你的问题。赠品是错误来自List.hd。如果列表为空，您只需要确定您想要的答案。可能答案是一个空列表。

let rotate ll =
    if ll = [] then
        []
    else
        let cons x y = x :: y in
        let init = List.map (fun _ -> []) (List.hd ll) in
        let rres = List.fold_right (List.map2 cons) ll init in
        List.rev rres

或者稍微有些笨拙：

let rotate = function
    | [] -> []
    | hd :: _ as ll -> 
        let cons x y = x :: y in
        let init = List.map (fun _ -> []) hd in
        let rres = List.fold_right (List.map2 cons) ll init in
        List.rev rres

但要回答您的实际问题，您可以使用ocamldebug在执行期间检查值。

在OCaml中打印嵌套列表

2 个答案: