如何比较Stata中的日期？

Question

我在Stata中有以下数据集

Id | date1    | date2
------------------------
1  | 28mar2005| 30jun2005
2  | 28mar2005| 31dec2005
3  | 28mar2005| 28febr2005
3  | 28mar2005| 30apr2005
3  | 28mar2005| 31dec2005

第二列的值对于所有观察都是相同的。考虑的年份在date1和date2中是相同的。

date2中的日期始终是相对月份的最后一天。

date2中的日期不会重复，并在Id中排序。

在Id中，我想保留数据集的观察结果，使得date1的“mm”与date2的“mm”之间的“时间距离”最小。在n个观测值之间无差异的情况下，我想在n个观测值中保持最后的观测值。因此，我想得到

Id | date1    | date2
------------------------
1  | 28mar2005| 30jun2005
2  | 28mar2005| 31dec2005
3  | 28mar2005| 30apr2005

我的想法是

（a）在date1和date2之间生成“绝对值距离”

（b）通过Id

找到最小绝对值距离

（c）如果某个Id被列出多次，请保持观察的最小绝对值距离

有什么建议吗？

Answer 1

我有些疑惑。

例如，如果30apr2005更接近28feb2005，您为什么要28mar2005？

我不确定你的意思是“如果n个观察之间没有差异......”，所以我自由地解释了。我调整了您的示例数据以反映这一点。请特别注意，有两个观察点对date1共享相同的date2和id == 3，但metric不同。我只保留一个。

clear
set more off

*----- example data -----

input ///
id str15(date1 date2)
1   28mar2005 30jun2005
2   28mar2005 31dec2005
3   28mar2005 28febr2005
3   28mar2005 28febr2005
3   28mar2005 30apr2005
3   28mar2005 31dec2005
end

set seed 128345
gen metric = floor(runiform()*100)

gen date11 = date(date1, "DMY")
gen date22 = date(date2, "DMY")

format %td date??

drop date?
list, sepby(id)

*----- what you want? -----

gen diff = abs(date11 - date22)

bysort id : gen obs = _n
bysort id (diff obs) : keep if diff == diff[1] 
by id: keep if _n == _N

list, sepby(id)

您可以在代码中保存sort，但如果它不会导致任何明显的速度减慢，我会离开它。

Answer 2

％td日期是整数，其中零是01/01/1960。这意味着减法将为您提供它们之间的日子：

clear 
input Id  str9 date1 str9 date2
1   28mar2005 30jun2005
2   28mar2005 31dec2005
3   28mar2005 28feb2005
3   28mar2005 30apr2005
3   28mar2005 31dec2005
3   27mar2005 27feb2005
end

gen DATE1 =date(date1,"DMY")
gen DATE2 =date(date2,"DMY")
format DATE? %td
drop date1 date2
rename DATE?, lower

gen diff = abs(date1-date2)
gsort Id diff -date2
bys Id: keep if _n==1

list, clean noobs

请注意，我添加了最后一行来创建＆＃34;无差异＆＃34;的实例。场景（如果在绝对距离方面存在联系，则保留较晚的日期2）。