如何从FsCheck.Gen.choose中提取int

Question

我是F＃的新手，无法看到如何从中提取int值：

let autoInc = FsCheck.Gen.choose(1,999)

编译器说类型为Gen<int>，但无法从中获取int！我需要将其转换为十进制，并且两种类型都不兼容。

Answer 1

从消费者的角度来看，您可以使用Gen.sample组合器，给定生成器（例如Gen.choose），它会返回一些示例值。

Gen.sample的签名是：

val sample : size:int -> n:int -> gn:Gen<'a> -> 'a list

(* `size` is the size of generated test data
   `n`    is the number of samples to be returned
   `gn`   is the generator (e.g. `Gen.choose` in this case) *)

您可以忽略size，因为Gen.choose会忽略它，因为它的分布是统一的，并执行以下操作：

let result = Gen.choose(1,999) |> Gen.sample 0 1 |> Seq.exactlyOne |> decimal

(* 0 is the `size` (gets ignored by Gen.choose)
   1 is the number of samples to be returned *)

result应该是关闭区间 [1,999] 中的值，例如 897

Answer 2

您好补充Nikos已经告诉您的内容，这是如何获得1到999之间的小数：

#r "FsCheck.dll"

open FsCheck

let decimalBetween1and999 : Gen<decimal> =
    Arb.generate |> Gen.suchThat (fun d -> d >= 1.0m && d <= 999.0m)

let sample () = 
    decimalBetween1and999
    |> Gen.sample 0 1 
    |> List.head 

您现在可以使用sample ()来获取随机小数。

如果您只想要1到999之间的整数，但将那些转换为decimal，您可以这样做：

let decimalIntBetween1and999 : Gen<decimal> =
    Gen.choose (1,999)
    |> Gen.map decimal

let sampleInt () = 
    decimalIntBetween1and999
    |> Gen.sample 0 1 
    |> List.head 

您可能 想要做什么

使用它来写一些不错的类型并检查这样的属性（这里使用Xunit作为测试框架和FsCheck.Xunit包：

open FsCheck
open FsCheck.Xunit

type DecTo999 = DecTo999 of decimal

type Generators = 
    static member DecTo999 =
        { new Arbitrary<DecTo999>() with
            override __.Generator = 
                Arb.generate 
                |> Gen.suchThat (fun d -> d >= 1.0m && d <= 999.0m)
                |> Gen.map DecTo999
        }

[<Arbitrary(typeof<Generators>)>]
module Tests =

  type Marker = class end

  [<Property>]
  let ``example property`` (DecTo999 d) =
    d > 1.0m

Answer 3

Gen<'a>是一种基本上抽象函数int -> 'a的类型（实际类型有点复杂，但现在让我们忽略）。这个函数是纯函数，即当给出相同的int时，你每次都会获得相同的'a back'实例。我们的想法是，FsCheck生成一堆随机整数，将它们提供给Gen函数，输出您感兴趣的'a类型的随机实例，然后将它们提供给测试。

所以你无法真正离开 int。你手中有一个给定int的函数，生成另一个int。

另一个答案中描述的

Gen.sample基本上只是向函数提供一系列随机整数并将其应用于每个函数，返回结果。

这个函数是纯函数很重要，因为它保证了可重复性：如果FsCheck找到一个测试失败的值，你可以记录输入Gen函数的原始int - 重新运行测试保证种子生成相同的值，即重现错误。