Question

如果我编写一个使用symb#快捷方式创建gensym然后绑定为全局变量的宏，则会反复生成完全相同的符号。但是，如果我手动调用gensym，它将正常运行。非常简单的例子：

(defmacro indirection
    [name & body]
    `(do (def name# ~@body)
         (defn ~name [] name#)))

(indirection foo 3)
(foo) ; ⇒ 3
(indirection goo 5)
(goo) ; ⇒ 5
(foo) ; ⇒ 5

如果您使用macroexpand：

，问题就很明显了

(macroexpand '(indirection foo 3))
(do (def name__2863__auto__ 3) (clojure.core/defn foo [] name__2863__auto__))
(macroexpand '(indirection foo 3))
(do (def name__2863__auto__ 3) (clojure.core/defn foo [] name__2863__auto__))

如果我长途呼叫gensym，这个问题就会消失：

(defmacro redirection
    [name & body]
    (let [rename (gensym)]
        `(do (def ~rename ~@body)
             (defn ~name [] ~rename))))

(redirection koo 3)
(koo) ; ⇒ 3
(redirection moo 5)
(moo) ; ⇒ 5
(koo) ; ⇒ 3

那么，为什么差异呢？我错过了什么？

Answer 1

`引用的语法实际上是reader macro;在评估之前，读者将其后面的形式（将文本翻译成Clojure形式）进行转换。这意味着在首次读取文本时，语法引用中以#结尾的任何符号仅转换为自动生成的符号一次;然后将自动生成的符号直接插入到宏定义中，并在每次调用该宏时在宏遍历中逐字显示。这可以在REPL中轻松说明：

user=> `(foo bar#)
(user/foo bar__2288__auto__)
user=> `(foo bar#)
(user/foo bar__2291__auto__)

使用#的自动生成符号的典型用例是在引用的let或fn形式内定义局部变量。在那里，重复使用相同的符号进行多次宏调用并不重要;它只需要在每次调用中都是唯一的。例如：

(defmacro indirection
  [name body]
  `(let [name# ~body]
     (defn ~name [] name#)))

（gensym）总是独一无二的，`（symb＃）不是 - 为什么？

1 个答案: