Question

我需要创建一个2列表，由未固定的数字图像填充，每个单元格一个图像，每行两个单元格。我们正在使用 XSL-FO

我将此XSL数据作为XSL的输入

<viewList>
    <views order="1">data:image/jpg;base64,/9j/4AAQSkZJRg...(base64 data)</views>
    <views order="2">data:image/jpg;base64,/9j/4AAQSkZ432...(base64 data)</views>
    <views order="3">data:image/jpg;base64,/9j/4AAQSkZdgd...(base64 data)</views>
    <views order="4">data:image/jpg;base64,/9j/4AAQSkZ775...(base64 data)</views>
    <views order="5">data:image/jpg;base64,/9j/4AAQSk7655...(base64 data)</views>
</viewList>

您可以注意到标记views的内容是base64信息，编码图像。我只是截断它们;它们很长。

对于渲染图像，我使用标记fo:external-graphic。所以，我设法将所有图像绘制在一个表中：

<fo:table>
<fo:table-body>   
    <xsl:for-each select="viewList/views">                                      
        <fo:table-row>
            <fo:table-cell>                                        
                <fo:block text-align="center">
                    <fo:external-graphic src="{current()}"/>
                </fo:block>                    
            </fo:table-cell>
        </fo:table-row>
    </xsl:for-each>
</fo:table-body>  
</fo:table>

如你所见;这不是完全有效的;因为每个单元格的图像...有关如何将它们放在2列中的任何想法吗？

Answer 1

实现此目的的一种方法是首先仅选择将成为每行中第一个单元格的views元素。

 <xsl:for-each select="viewList/views[position() mod $cellsPerRow = 1]">

（其中 cellsPerRow 是一个设置为2的变量，这样可以让您轻松更改每行的单元格数）。这将构成您fo:table-row）

的基础

然后，要选择实际形成该行的单元格，您可以执行此操作

<xsl:for-each select="self::*|following-sibling::views[position() &lt; $cellsPerRow]" >

试试这个XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="fo" version="2.0">
    <xsl:output method="xml" encoding="UTF-8" indent="yes" />

    <xsl:param name="cellsPerRow" select="2" />
    <xsl:template match="/">
        <fo:table>
            <fo:table-body>   
                <xsl:for-each select="viewList/views[position() mod $cellsPerRow = 1]">                                      
                    <fo:table-row>
                        <xsl:apply-templates select="self::*|following-sibling::views[position() &lt; $cellsPerRow]" />
                    </fo:table-row>
                </xsl:for-each>
            </fo:table-body>  
        </fo:table>
    </xsl:template>

    <xsl:template match="views">
        <fo:table-cell>                                        
            <fo:block text-align="center">
                <fo:external-graphic src="{current()}"/>
            </fo:block>                    
        </fo:table-cell>
    </xsl:template>
</xsl:stylesheet>

注意，我已经从使用xsl:for-each切换到xsl:apply-templates主要是为了避免答案中的过度缩进。

XSL-FO两列表

1 个答案: