Question

在VBA中使用smple类的机制有几个非常好的问题：When to use a Class in VBA?和What are the benefits of using Classes in VBA?

作为一个与OOP和类相关的人，很难知道如何实现它们，或者甚至是真正可能的。

例如，我必须处理多个工作表中的大范围，我需要获得许多不同的数据子集。 “做x的代理人”和“有y的客户”......等等。这里有一个小组，用于了解拥有2个以上客户的代理商数量：

Sub agent_subset(output_sheet As String, _
                                    Input_sheet_name As String, _
                                    email_col As Integer, _
                                    vendor_count_col As Integer, _
                                    client_count_col As Integer, _
                                    modified_col As Integer, _
                                    num_of_clients As Integer)
'  get a list of all agents with 2 or more clients and put them into a sheet

    Application.DisplayStatusBar = True

    Dim sheet_rows As Long
    sheet_rows = Worksheets(Input_sheet_name).Cells(rows.Count, 1).End(xlUp).Row

    Dim email_range As Range ' range of agent emails
    Dim client_count_range As Range ' range of client count
    Dim vendor_count_range As Range ' range of vendor count
    Dim modified_range As Range ' range of modified at

    With Worksheets(Input_sheet_name)
        Set email_range = .Range(.Cells(2, email_col), .Cells(sheet_rows, email_col))
        Set client_count_range = .Range(.Cells(2, client_count_col), .Cells(sheet_rows, client_count_col))
        Set vendor_count_range = .Range(.Cells(2, vendor_count_col), .Cells(sheet_rows, vendor_count_col))
        Set modified_range = .Range(.Cells(2, modified_col), .Cells(sheet_rows, modified_col))
    End With

    Dim n As Long
    Dim counter As Long
    counter = 0

    Dim modified_array() As String

    For n = 2 To sheet_rows
        If client_count_range(n, 1).Value > num_of_clients Then
            counter = counter + 1
            Worksheets(output_sheet).Cells(counter + 1, 1).Value = email_range(n, 1).Value
            Worksheets(output_sheet).Cells(counter + 1, 2).Value = client_count_range(n, 1).Value
            Worksheets(output_sheet).Cells(counter + 1, 3).Value = vendor_count_range(n, 1).Value
                modified_array() = Split(modified_range(n, 1).Value, "T")
            Worksheets(output_sheet).Cells(counter + 1, 4).Value = modified_array(0)
        End If

         Application.StatusBar = "Loop status: " & n & "of " & sheet_rows

    Next n

Worksheets(output_sheet).Cells(counter + 3, 1).Value = "Last run was " & Now()

Application.StatusBar = False

End Sub

效果很好，但现在我希望根据其他标准获得更小的代理和客户端子集。所以，我将编写一个类似的函数，操纵类似的数据。我的直觉告诉我，使用课程会让我的生活更轻松，但我不知道如何完成任务。

是否应该有一个Agent类，其中包含有关代理的所有信息？和/或客户类？或者，这些课程是否应该用于查看整个范围或表格？

我不是在寻找具体的代码，而是一种如何解决问题的方法。

Answer 1

我必须处理多张照片中的大范围

如果您考虑计算机，那么您的代码将非常实用。这些范围代表真实的东西（代理商，客户，发票，交易），所以请用这些术语来思考。

我会有一个代理类，它拥有代理的所有属性。我会有一个代理集合类，它包含我所有的代理类。然后，在我的Agents类中，我将使用Filter方法返回Agents类的子集。

以下是一个例子：我有客户。客户可以是否有效。客户还有一个我通过电子邮件发送某些信息时使用的模板。当我想向使用Table1模板的活跃客户发送电子邮件时，它看起来像这样

Set clsCustomersToEmail = clsCustomers.FilterOnActive(True).FilterOnTemplate("Table1")
For Each clsCustomer in clsCustomersToEmail
    'Do stuff
Next clsCustomer`

在我的CCustomers集合类中，我有几个返回CCustomers类的属性，其客户数量少于大的CCustomers类（称为clsCustomers）

Public Property Get FilterOnActive() As CCustomers

    Dim clsReturn As CCustomers
    Dim clsCustomer As CCustomer

    Set clsReturn = New CCustomers

    For Each clsCustomer In Me
        If clsCustomer.Active Then
            clsReturn.Add clsCustomer
        End If
    Next clsCustomer

    Set FilterOnActive = clsReturn

End Property
Public Property Get FilterOnTemplate(ByVal sTemplate As String) As CCustomers

    Dim clsReturn As CCustomers
    Dim clsCustomer As CCustomer

    Set clsReturn = New CCustomers

    For Each clsCustomer In Me
        If clsCustomer.Template.TemplateName = sTemplate Then
            clsReturn.Add clsCustomer
        End If
    Next clsCustomer

    Set FilterOnTemplate = clsReturn

End Property

当我想要做一些事情，比如将一堆客户数据写入范围时，我创建一个返回数组的属性，并将数组写入范围。

Set clsCustomersPastDue = clsCustomers.FilterOnActive(True).FilterOnPastDue(True)
vaWrite = clsCsutomerPastDue.AgingReport
rCell.Resize(UBound(vaWrite,1),UBound(vaWrite,2)).Value = vaWrite

我倾向于想到我编码的物理内容。它们不一定是有形的东西，但是如果你能把它带回有形的东西，这可能会有所帮助。

交易是一件事。但如果该交易是发票，现在确定该对象的属性变得容易。例如，您可以查看纸质发票并查看属性。

下一个层次是关系。每个Agent类都有客户。因此，您的Agent对象应具有返回CCustomers类的Customers属性。或者，如果它在现实生活中没有紧密结构，也许您的CCustomers类具有FilterOnAgent属性，该属性返回您正在寻找的客户子集。

使用类在excel vba中使用多个范围

1 个答案: