Question

我很难理解如何让我的代码显示由偶数和奇数组成的隔离列表。我甚至不确定我的理解缺乏什么。我显然是这种语言的新手，必须用它来上学。我的命令性和功能性的头脑不会让我知道这到底是怎么回事。

现在，不，我不是要你做我的作业！我只是要求你帮助我看看我缺乏理解力。我也查找了类似的答案，但我无法将它们转换为我应该编写此函数的方式。

请再一次，不要像我以前经常被殴打一样打击我。请帮助我看看我的理解缺乏什么。不要只是给我答案和代码片段而不解释它。

这是：

is_even(H) :-
   0 is mod(H, 2).

segregate(List, Even, Odd) :- segregator(List, Even, Odd).

segregator([], [], []).
segregator([H|T], E, O) :-
    is_even(H),
    % I feel here is where I am supposed to build the list, 
    % but I have no clue how since Even or Odd has not been unified.
    segregator(T, E, O),
    write('Even is '), write(E), nl.
segregator([H|T], E, O) :-
    % Same here as above.
    segregator(T, E, O),
    write('Odd is '), write(O), nl.

Answer 1

逻辑上纯粹的实施非常简单，感谢clpfd：

:- use_module(library(clpfd)).

list_evens_odds([],[],[]).
list_evens_odds([X|Xs],[X|Es],Os) :-
   X mod 2 #= 0,
   list_evens_odds(Xs,Es,Os).
list_evens_odds([X|Xs],Es,[X|Os]) :-
   X mod 2 #= 1,
   list_evens_odds(Xs,Es,Os).

我们希望成功的一些示例查询（使用有限的答案序列）：

?- Xs = [1,2,3,4,5,6,7], list_evens_odds(Xs,Es,Os).
Xs = [1,2,3,4,5,6,7],
Es = [  2,  4,  6  ],
Os = [1,  3,  5,  7] ;
false.

?- list_evens_odds(Ls,[2,4],[1,3]).
Ls = [2,4,1,3] ? ;
Ls = [2,1,4,3] ? ;
Ls = [2,1,3,4] ? ;
Ls = [1,2,4,3] ? ;
Ls = [1,2,3,4] ? ;
Ls = [1,3,2,4] ? ;
no

我们希望失败的查询怎么办？

?- list_evens_odds(Ls,[2,4,5],[1,3]).
no
?- list_evens_odds(Ls,[2,4],[1,3,6]).
no
?- list_evens_odds([_,_,_],[2,4],[1,3]).
no

最后，最常见的查询：

?- assert(clpfd:full_answer).
yes

?- list_evens_odds(Ls,Es,Os).
Ls = [],   Es = [],   Os = []                              ? ;
Ls = [_A], Es = [_A], Os = [], _A mod 2#=0, _A in inf..sup ? ...

编辑2015-05-06

这是使用logical-purity进行此操作的另一种方式！

将元谓词tpartition/4与zeven_t/2或zodd_t/2一起使用。

bool01_t(1,true).
bool01_t(0,false).

zeven_t(Z,Truth) :- Z mod 2 #= 0 #<==> B, bool01_t(B,Truth).

%zodd_t(Z,Truth) :- Z mod 2 #= 1 #<==> B, bool01_t(B,Truth).
zodd_t(Z,Truth)  :- Z mod 2 #=         B, bool01_t(B,Truth). % tweaked

zeven_t/2统一整数的均匀度，zodd_t/2 奇数。

一切就绪后，让我们运行一些查询！

?- tpartition(zeven_t,[1,2,3,4,5,6,7],Es,Os).
Es = [2,4,6], Os = [1,3,5,7].
?- tpartition(zodd_t ,[1,2,3,4,5,6,7],Os,Es). % argument order differs
Es = [2,4,6], Os = [1,3,5,7].

确定性地成功。使用list_evens_odds/3的等效查询不会。

在Prolog中隔离列表

1 个答案:

编辑2015-05-06