Question

我想在 cython 中使用另一个 numpy.array 的给定大小制作一个boolean numpy数组，但它会引发错误消息：

CosmoTest.pyx

import numpy as np
cimport numpy as np
cimport cython
from libcpp cimport bool
x=np.array([[-0.3,1.2],[2.5,0.82],[0.61,-0.7]])
mask= np.ones_like(x,dtype=bool)

错误：

        mask= np.ones_like(x,dtype=bool)
                                      ^
------------------------------------------------------------

CosmoTest.pyx:318:39: 'bool' is not a constant, variable or function identifier

如何在cython中定义？

更新

cpdef np.ndarray arc( np.ndarray x):
    cdef np.ndarray[double, ndim=1, mode='c'] out = np.zeros_like(x)
    cdef np.ndarray[np.uint8_t,cast=True, ndim=1] mask = (x < 0.999).view(dtype=np.uint8)
    if mask.any():
        out[mask] = 0.5*np.log((1.+((1.-x[mask])/(x[mask]+1.))**0.5)/(1.-((1.-x[mask])/(x[mask]+1.))**0.5))/(1-x[mask]**2)**0.5

    cdef np.ndarray[np.uint8_t,cast=True, ndim=1] mask = (x > 1.001).view(dtype=np.uint8)
    if mask.any():
        out[mask] = np.arctan(((x[mask]-1.)/(x[mask]+1.))**0.5)/(x[mask]**2 - 1)**0.5

    cdef np.ndarray[np.uint8_t,cast=True , ndim=1] mask = ((x >= 0.999) & (x <= 1.001)).view(dtype=np.uint8)
    if mask.any():
        out[mask] = 5./6. - x[mask]/3.

    return out

错误消息：

Error compiling Cython file:
------------------------------------------------------------
...
        if mask.any():
            out[mask] = 0.5*np.log((1.+((1.-x[mask])/(x[mask]+1.))**0.5)/(1.-((1.-x[mask])/(x[mask]+1.))**0.5))/(1-x[mask]**2)**0.5

        cdef np.ndarray[np.uint8_t,cast=True, ndim=1] mask = (x > 1.001).view(dtype=np.uint8)
        if mask.any():
            out[mask] = np.arctan(((x[mask]-1.)/(x[mask]+1.))**0.5)/(x[mask]**2 - 1)**0.5
                                                      ^
------------------------------------------------------------

CosmoTest.pyx:9:55: local variable 'mask' referenced before assignment

Answer 1

如果您将代码的最后一行更改为

mask= np.ones_like(x,dtype=np.bool)

它会工作（从{numpy取bool而不是尝试使用lipcpp定义）。但是，实际上静态输入布尔numpy数组目前还不能正常工作（参见Passing a numpy pointer (dtype=np.bool) to C++）。

目前最好的方法是静态输入

def f(np.ndarray[dtype=np.int8_t,ndim=1] x):
    cdef np.ndarray[dtype=np.int8_t,ndim=1] y
    y = np.ones_like(x,dtype=np.int8)
    return y.view(dtype=np.bool) # returns as boolean array

内部numpy使用8位整数来存储bool，因此您只需使用view重新解释数组而无需复制。

如果你有一个布尔数组并且想要调用f，那你就

mask = np.array([True,False,True])
f(mask.view(dtype=np.int8))

您可以随时编写一个小包装函数作为f的公共接口，以自动进行重新解释。

它比它需要的更加繁琐，但它可以使用。

添加以回应评论

我链接的文章建议使用cast=True：

cdef np.ndarray[np.uint8_t,cast=True] mask = (x > 0.01)

这也很好。写在我的方法中

cdef np.ndarray[np.uint8_t] mask = (x > 0.01).view(dtype=np.uint8)

（即没有演员，但有view）。据我所知，没有实际区别，所以选择你认为哪一个看起来更好。

已修改以回应其他问题

下面的工作代码（我已经检查过并且编译了 - 我还没有检查确保它运行）。您收到了编译器错误，因为您多次定义了mask的类型。每个函数每个变量只允许使用cdef一次，但是已经根据需要定义了可以分配给它的类型。

cpdef np.ndarray arc( np.ndarray x):
    cdef np.ndarray[double, ndim=1, mode='c'] out = np.zeros_like(x)
    cdef np.ndarray[np.uint8_t, ndim=1] mask = (x < 0.999).view(dtype=np.uint8)
    if mask.any():
        out[mask] = 0.5*np.log((1.+((1.-x[mask])/(x[mask]+1.))**0.5)/(1.-((1.-x[mask])/(x[mask]+1.))**0.5))/(1-x[mask]**2)**0.5

    mask = (x > 1.001).view(dtype=np.uint8) # REMOVED cdef!
    if mask.any():
        out[mask] = np.arctan(((x[mask]-1.)/(x[mask]+1.))**0.5)/(x[mask]**2 - 1)**0.5

    mask = ((x >= 0.999) & (x <= 1.001)).view(dtype=np.uint8) # REMOVED cdef!
    if mask.any():
        out[mask] = 5./6. - x[mask]/3.

    return out

（我还从定义中删除了cast=True。这并不重要。您可以使用它，也可以使用view(dtype=np.uint8)。如果您愿意，可以同时使用两者。但它打字更多！）

制作一个布尔数组

1 个答案: