Question

给定一个列表，例如[1,2,3,7,2,5,8,9,3,4]如何在列表中提取序列？

一个序列被定义为一个有序列表（通常我会说n元组，但我在prolog中被告知一个元组被称为一个序列）。因此，我们希望在下一个元素小于前一个元素的位置剪切列表。

因此对于列表[1,2,3,7,2,5,8,9,3,4]，它应该返回：

[ [1,2,3,7], [2,5,8,9], [3,4] ] %ie we have cut the list at position 4 & 8.

对于本练习，您不能使用构造;或->

非常感谢提前！

示例结果：

EG1。

?-function([1,2,3,7,2,5,8,9,3,4],X): %so we cut the list at position 4 & 9

X = [ [1,2,3,7], [2,5,8,9], [3,4] ]。

EG2。

?-function([1,2,3,2,2,3,4,3],X): %so we cut the list at position 3,4 & 8

X = [ [1,2,3], [2], [2,3,4], [3] ].

希望这有助于澄清问题。如果您需要进一步说明，请告诉我！再次感谢您提供的任何帮助。

Answer 1

首先，让我们在概念上分解它。谓词list_ascending_rest/3定义列表Xs，最左边的最长子列表Ys和剩余项Rest之间的关系。我们将像以下查询一样使用它：

?- Xs = [1,2,3,7,2,5,8,9,3,4], list_ascending_rest(Xs,Ys,Rest).
Ys   = [1,2,3,7],
Rest = [2,5,8,9,3,4] ;
false.

直截了当的谓词定义如下：

:- use_module(library(clpfd)).

list_ascending_rest([],[],[]).
list_ascending_rest([A],[A],[]).
list_ascending_rest([A1,A2|As], [A1], [A2|As]) :-
    A1 #>= A2.
list_ascending_rest([A1,A2|As], [A1|Bs], Cs) :-
    A1 #< A2,
    list_ascending_rest([A2|As], Bs,Cs).

然后，让我们实现谓词list_ascendingParts/2。该谓词对每个部分重复使用list_ascending_rest/3，直到没有留下任何内容。

list_ascendingParts([],[]).
list_ascendingParts([A|As],[Bs|Bss]) :-
    list_ascending_rest([A|As],Bs,As0),
    list_ascendingParts(As0,Bss).

示例查询：

?- list_ascendingParts([1,2,3,7,2,5,8,9,3,4],Xs).
Xs = [[1,2,3,7], [2,5,8,9], [3,4]] ;
false.

?-  list_ascendingParts([1,2,3,2,2,3,4,3],Xs).
Xs = [[1,2,3], [2], [2,3,4], [3]] ;
false.

编辑2015/04/05

如果已知升序部分但列表未知，该怎么办？我们来看看：

?- list_ascendingParts(Ls, [[3,4,5],[4],[2,7],[5,6],[6,8],[3]]).
Ls = [3,4,5,4,2,7,5,6,6,8,3] ? ;
no

让我们不要忘记使用list_ascendingParts/2的最常见查询：

?- assert(clpfd:full_answer).
yes

?- list_ascendingParts(Ls, Ps).
Ls = [],      Ps = []                                                   ? ;
Ls = [_A],    Ps = [[_A]]                                               ? ;
Ls = [_A,_B], Ps = [[_A],[_B]], _B#=<_A, _B in inf..sup, _A in inf..sup ? ...

编辑2015-04-27

改善的空间？是的，肯定是！

通过使用元谓词splitlistIfAdj/3，可以“确定性地成功”和“在需要时使用非确定性”，具体取决于具体情况。

splitlistIfAdj/3基于@ this答案中@false提出的if_/3。因此传递给它的谓词必须遵守与(=)/3和memberd_truth/3相同的约定。

所以我们定义(#>)/3和(#>=)/3：

#>=(X,Y,Truth) :- X #>= Y #<==> B, =(B,1,Truth).
#>( X,Y,Truth) :- X #>  Y #<==> B, =(B,1,Truth).

让我们使用splitlistIfAdj(#>=)重新询问上述问题而不是list_ascendingParts：

?- splitlistIfAdj(#>=,[1,2,3,7,2,5,8,9,3,4],Pss).
Pss = [[1,2,3,7],[2,5,8,9],[3,4]].        % succeeds deterministically
?- splitlistIfAdj(#>=,[1,2,3,2,2,3,4,3],Pss).
Pss = [[1,2,3],[2],[2,3,4],[3]].          % succeeds deterministically

?- splitlistIfAdj(#>=,Ls,[[3,4,5],[4],[2,7],[5,6],[6,8],[3]]).
Ls = [3,4,5,4,2,7,5,6,6,8,3] ;            % works the other way round, too
false.                                    % universally terminates

最后，最常见的查询。我想知道答案是什么样的：

?- splitlistIfAdj(#>=,Ls,Pss).
Ls = Pss,              Pss = [] ;
Ls = [_G28],           Pss = [[_G28]] ;
Ls = [_G84,_G87],      Pss = [[_G84],[_G87]],        _G84#>=_G87 ;
Ls = [_G45,_G48,_G41], Pss = [[_G45],[_G48],[_G41]], _G45#>=_G48, _G48#>=_G41 
% and so on...

Answer 2

评论中建议的

maplist/3不会帮助您，因为maplist/3擅长获取列表并将每个元素映射到其他内容的相同大小的集合中，或者建立一个所有单个元素之间的关系均匀。在此问题中，您尝试收集具有某些属性的连续子列表。

这是一个DCG解决方案。这里的想法是将列表检查为一系列递增序列，其中在它们之间的边界处，先前序列的最后一个元素小于或等于以下序列的第一个元素（如问题陈述基本上表示的那样）

% A set of sequences is an increasing sequence ending in X
%    followed by a set of sequences that starts with a value =< X
sequences([S|[[Y|T]|L]]) --> inc_seq(S, X), sequences([[Y|T]|L]), { X >= Y }.
sequences([S]) --> inc_seq(S, _).
sequences([]) --> [].

% An increasing sequence, where M is the maximum value
inc_seq([X,Y|T], M) --> [X], inc_seq([Y|T], M), { X < Y }.
inc_seq([X], X) --> [X].

partition(L, R) :- phrase(sequences(R), L).

| ?- partition([1,2,3,4,2,3,8,7], R).

R = [[1,2,3,4],[2,3,8],[7]] ? ;

(1 ms) no
| ?-  partition([1,2,3,2,2,3,4,3],X).

X = [[1,2,3],[2],[2,3,4],[3]] ? ;

(1 ms) no

规则sequences([]) --> [].的唯一原因是您希望partition([], [])成立。否则，该规则是不必要的。

提取序列（列表）Prolog

2 个答案:

编辑2015/04/05

编辑2015-04-27