在ComboBox中显示多个列内容

Question

我想在Combobox下拉菜单中显示FirstName和LastName 问题是我应该在表中存在的2个字段上工作 我检查了TDBlLookUpComboBox但是ListFields属性在Delphi Xe中对我不起作用。

我将TDBlLookUpComboBox的属性设置为

DataSource :my datasource
ListFields : SUR_NAME;  FIRST_NAME

现在，我是以一种基本的方式做到的：

nameClient := Concat( sqlqry1.Fields.FieldByName('FIRST_NAME').AsString,' ',
                      sqlqry1.Fields.FieldByName('SUR_NAME').AsString);
cbbClient.Items.Add(nameClient); 

Answer 1

更改输入
只需通过输入查询来更改进入DBCombo的源数据：

select concat(SUR_NAME,' ',FIRST_NAME) as NAME, * from mytable;

现在，您可以在组合框中显示数据。

使组合框中的输出看起来不错
_{显然你会使用TDBILookUpComboBox，但其他一切都是一样的。}

为了在下拉列表中创建多个列，您必须自己创建绘图。

这可以通过将style更改为csOwnerDrawFixed并指定OnDrawItem事件来完成。

请参阅下面的示例代码：

unit Unit18;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm18 = class(TForm)
    ComboBox1: TComboBox;
    procedure ComboBox1DrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);
  private
  public
  end;

var
  Form18: TForm18;

implementation

uses
  System.Types,
  StrUtils;

{$R *.dfm}

procedure TForm18.ComboBox1DrawItem(Control: TWinControl; Index: Integer; Rect: TRect; State: TOwnerDrawState);
var
  Columns: TStringDynArray;
  ColCount: Integer;
  ItemText: string;
  DC: HDC;
  DrawRect: TRect;
  Middle: integer;
begin
  ItemText:= ComboBox1.Items[index];
  Columns:= SplitString(ItemText, '|');
  ColCount:= Length(Columns);

  // For Demo purposes only the first 2 columns are displayed.
  DC:= ComboBox1.Canvas.Handle;
  Combobox1.Canvas.FillRect(Rect);
  Middle:= Rect.Left + Rect.Width div 2;
  Combobox1.Canvas.MoveTo(Middle, Rect.Top);
  Combobox1.Canvas.LineTo(Middle, Rect.Bottom);
  if ColCount > 0 then begin
    DrawRect:= Rect;
    OffsetRect(DrawRect,1,0);
    DrawRect.Right:= DrawRect.Right - DrawRect.Width div 2;
    DrawText(DC, Columns[0], Length(Columns[0]), DrawRect, 0);
  end;
  if ColCount > 1 then begin
    DrawRect:= Rect;
    OffsetRect(DrawRect,1,0);
    DrawRect.Left:= DrawRect.Left + DrawRect.Width div 2;
    DrawText(DC, Columns[1], Length(Columns[1]), DrawRect, 0);
  end;
end;

end.

将以下文字放在Items：

中

  

测试|测试
  line2 |第2部分
  第4行|第三部分
  第6行

这将是显示的内容：