Question

我正在使用泛型来定义自己拥有通用列表的对象列表。我编写了一种方法，使用基本上执行相同操作的特定方法检索每个列表的聚合。以下是结构：

unit Unit1;

interface

uses
 System.Generics.Collections;

type
  TListType=(ltSType,ltFType);

  TMyList<T> = class(TList<T>)
   {Do some stuff in here to help load lists etc}
  end;

  TListObject=class(TObject)
  private
    FSList:TMyList<string>;
    FIList:TMyList<integer>;
    function GetSList: TMyList<string>;
    function GetIList: TMyList<integer>;
  public
    property MySList:TMyList<string> read GetSList;
    property MyIList:TMyList<integer> read GetIList;
    constructor create;
  end;

  TListOfObject<T:TListObject> = class(TObjectList<T>)
  public
    Function AggrSList:TMyList<string>;
    Function AggrIList:TMyList<integer>;
  end;

implementation

{ TListObject }

constructor TListObject.create;
begin
  FSList:=TMyList<string>.create;
  FIList:=TMyList<integer>.create;
end;

function TListObject.GetIList: TMyList<integer>;
begin
  result:=FIlist;
end;

function TListObject.GetSList: TMyList<string>;
begin
  result:=FSList;
end;


{ TListOfObject<T> }

function TListOfObject<T>.AggrIList: TMyList<integer>;
var
  i,j:integer;

begin
  result:=TMyList<integer>.create;
  for I := 0 to count-1 do
    for j := 0 to items[i].MyIList.Count-1 do
      result.Add(items[i].MyIList[j]);
end;

function TListOfObject<T>.AggrSList: TMyList<string>;
var
  i,j:integer;
begin
  result:=TMyList<string>.create;
  for I := 0 to count-1 do
    for j := 0 to items[i].MySList.Count-1 do
      result.Add(items[i].MySList[j]);
end;

end.

我仍然对泛型相当新，但认为AggrIList和AggrSlist的聚合方法可以使用泛型来编写，这些泛型使用单个方法来提取数据然后在结果中进行转换。

这是可能的，我将如何处理？我打算做一些更高级的功能，也可以从这种方法中受益。

Answer 1

您可以使用（伪代码）：

TNestedList<T> = class(TList<TList<T>>)
  function GetAggregateList : TList<T>;
end;

function TNestedList<T>.GetAggregateList : TList<T>;

var
  List : TList<T>;
  Item : T;

begin
  Result := TList<T>.Create;
  for List in Self do
    for Item in List do
      Result.Add(Item);
  end;

无需针对特定类型实施GetAggregateList - 这是您使用泛型的内容。

另请注意，调用方法CreateAggregateList（以明确调用方负责销毁已创建的列表）或将已创建的列表实例传入过程可能更好：

procedure GetAggregateList(List : TList<T>);

...将列表所有权完全留给调用者，这在Delphi中是一种非常常见的模式。

Delphi泛型方法

1 个答案: