Question

我正在尝试以下代码：

proc IML;
do i=1 to 20;  
[some codes to execute]  
data[i];  
end;  
QUIT;

所以我希望在完成do循环后获得20个数据集。是否可以在 SAS ？我可以使用宏来做，但我不喜欢在PROC IML中使用宏！

提前致谢。

Answer 1

如果你有SAS / IML 12.1，它在2012年8月作为SAS 9.3m2的一部分发货，那么你可以将每个数据集的名称括在括号中，如下所示

proc iml;
names = "Data1":"Data20";
do i = 1 to ncol(names);
   x = i;
   dsname = names[i];   /* construct each name */
   create (dsname) from x;
   append from x;
   close (dsname);
end;

有关完整的计划和说明，请参阅文章"Read data sets that are specified by an array of names."

中的最后一个示例

Answer 2

是的，使用模块内的CALL EXECUTE子程序。

proc iml;
file LOG;

output = (1:10)`;

/*This is how you create a data set from a matrix*/
create outdata from output;
append from output;
close outdata;

/*This module will create 1 data set for each variable in OUTPUT*/
start loopit;
do i=1 to 10;
    x = output[i];
    /*build the string you want to execute*/
    outStr = 'create outdata' + catt(i) + " from x; append from x; close outdata" + catt(i) + ";";
    put outStr; /*Print the string to the log*/

    /*Execute the string*/
    call execute(outStr);
end;
finish loopit;

/*Call the module*/
call loopit;

quit;

如何在SAS / IML中使用do循环创建多个数据集？

2 个答案: