Question

我正在尝试使用FParsec为F＃中的Mathematica语言编写解析器。

我为MiniML编写了一个支持语法f x y = (f(x))(y)的函数应用程序具有高优先级。现在我需要使用相同的语法来表示f*x*y，因此，它具有与multiply相同的优先级。特别是x y + 2 = x*y + 2而x y ^ 2 = x * y^2。

如何实现这一目标？

Answer 1

正如Stephan在评论中指出的那样，您可以将运算符解析器拆分为两个单独的解析器，并将自己的解析器放在中间，用于空格分隔的表达式。以下代码演示了这一点：

#I "../packages/FParsec.1.0.1/lib/net40-client"
#r "FParsec"
#r "FParsecCS"

open FParsec
open System.Numerics

type Expr =
  | Int of BigInteger
  | Add of Expr * Expr
  | Mul of Expr * Expr
  | Pow of Expr * Expr

let str s = pstring s >>. spaces
let pInt : Parser<_, unit> = many1Satisfy isDigit |>> BigInteger.Parse .>> spaces
let high = OperatorPrecedenceParser<Expr,unit,unit>()
let low = OperatorPrecedenceParser<Expr,unit,unit>()
let pHighExpr = high.ExpressionParser .>> spaces
let pLowExpr = low.ExpressionParser .>> spaces

high.TermParser <-
  choice
    [ pInt |>> Int
      between (str "(") (str ")") pLowExpr ]

low.TermParser <-
  many1 pHighExpr |>> (function [f] -> f | fs -> List.reduce (fun f g -> Mul(f, g)) fs) .>> spaces

low.AddOperator(InfixOperator("+", spaces, 10, Associativity.Left, fun f g -> Add(f, g)))
high.AddOperator(InfixOperator("^", spaces, 20, Associativity.Right, fun f g -> Pow(f, g)))

run (spaces >>. pLowExpr .>> eof) "1 2 + 3 4 ^ 5 6"

输出结果为：

Add (Mul (Int 1,Int 2),Mul (Mul (Int 3,Pow (Int 4,Int 5)),Int 6))

代表预期的1 * 2 + 3 * 4^5 * 6。

解析＆＃34; x y z＆＃34;优先乘法

1 个答案: