Question

我想删除（sed或awk）所有只包含一次字符的所有行的换行符。但是一旦在线上删除换行符，就可以删除以下行。

这是一个例子

line1"test 2015"
line2"test
2015"
line3"test 2020"
line4"test
2017"

应转换为：

line1"test 2015"
line2"test2015"
line3"test 2020"
line4"test2017"

Answer 1

使用sed：

sed '/[^"]$/{N;s/\n//}' file

输出：

line1"test 2015"
line2"test2015"
line3"test 2020"
line4"test2017"

使用单个字符//搜索（^）非（$）结束（"）的行。仅对这些行（{}）：将下一行（N）附加到sed的模式空间（当前行）并使用sed的搜索并替换（s///）以在模式空间中查找嵌入换行符（\n）并替换为空。

Answer 2

使用GNU awk：

awk -v RS='"' 'NR % 2 == 0 { gsub(/\n/, ""); } { printf("%s%s", $0, RT) }' filename

这是最简单的方法。使用"作为记录分隔符，

NR % 2 == 0 {             # in every other record (those inside quotes)
  gsub(/\n/, "")          # remove the newlines
}
{ 
  printf("%s%s", $0, RT)  # then print the line terminated by the same thing
                          # as in the input (to avoid an extra quote at the
                          # end of the output)
}

RT是一个GNU扩展，这就是为什么这需要gawk。

使用sed

使用sed执行此操作的难度可能是引号之间可能有两个换行符，例如

line2"test
123
2015"

这使得条件变脆后只能获取一行。因此：

sed '/^[^"]*"[^"]*$/ { :a /\n.*"/! { N; ba; }; s/\n//g; }' filename

那是：

/^[^"]*"[^"]*$/ {   # When a line contains only one quote
  :a                # jump label for looping
  /\n.*"/! {        # until there appears another quote
    N               # fetch more lines
    ba
  }
  s/\n//g           # once done, remove the newlines.
}

作为单行，这需要GNU sed，因为BSD sed对分支指令的格式化很挑剔。但是，应该可以将扩展形式的代码放入文件中，例如foo.sed，然后使用BSD sed运行sed -f foo.sed filename。

请注意，此代码假定在打开引号后，其中包含引号的下一行仅包含该引号。如果需要，解决该问题的方法是

sed ':a h; s/[^"]//g; s/""//g; /"/ { x; N; s/\n//; ba }; x' filename

......但这可能超出了sed可以合理完成的事情范围。它的工作原理如下：

:a           # jump label for looping
h            # make a copy of the line
s/[^"]//g    # isolate quotes
s/""//g      # remove pairs of quotes
/"/ {        # if there is a quote left (number of quotes is odd)
  x          # swap the unedited text back into the pattern space
  N          # fetch a new line
  s/\n//     # remove the newline between them
  ba         # loop
}
x            # swap the text back in before printing.

使用非GNU awk

每行几个引号的情况在awk中比在sed中更容易处理。上面的GNU awk代码是隐含的;对于非GNU awk，它需要做更多的事情（但不是非常如此）：

awk -F '"' '{ n = 0; line = ""; do { n += NF != 0 ? NF - 1 : 0; line = line $0 } while(n % 2 == 1 && getline == 1) print line }' filename

主要技巧是使用"作为字段分隔符，以便字段数告诉我们行中有多少引号。然后：

{
                                       # reset state
  n = 0                                # n is the number of quotes we have
                                       # seen so far
  line = ""                            # line is where we assemble the output
                                       # line

  do {
    n += NF != 0 ? NF - 1 : 0;         # add the number of quotes in the line
                                       # (special handling for empty lines
                                       # where NF == 0)
    line = line $0                     # append the line to the output
  } while(n % 2 == 1 && getline == 1)  # while the number of quotes is odd
                                       # and there's more input, get new lines
                                       # and loop

  print line                           # once done, print the combined result.
}

Answer 3

这可能适合你（GNU sed）：

sed -r ':a;N;s/^([^\n"]*"[^\n"]*)\n/\1 /;ta;P;D' file

这将替换两行之间的换行符，其中第一行只包含一个双引号。

N.B。空间也可能被删除，但数据表明了这一点。

SED删除包含图案的新线条

3 个答案:

使用GNU awk：

使用sed

使用非GNU awk