Question

我想在Perl6中制作一个modulino (a file that can run as either a module or a script)。

以下代码＆＃34;流程＆＃34;命令行中的文件名：

sub MAIN ( *@filenames )
{
    for @filenames -> $filename
    {
        say "Processing $filename";
    }
}

将其保存为main.pm6我可以运行它并且可以正常运行：

perl6 main.pm6 hello.txt world.txt
Processing 'hello.txt'
Processing 'world.txt'

所以，我希望这是一个模块，以便我可以添加功能并使测试更容易。但是，当我向其添加module声明时，它不再输出任何内容：

module main;
sub MAIN ( *@filenames )
{
    for @filenames -> $filename
    {
        say "Processing '$filename'";
    }
}

这导致没有输出：

perl6 main.pm6 hello.txt world.txt

那么，我如何在Perl6中构建modulino？

我正在MoarVM使用January 2015 release of Rakudo Star上运行的Perl6。

UPDATE：

当我尝试将模块包装在大括号中时：

module main
{
    sub process (@filenames) is export
    {
        for @filenames -> $filename
        {
            say "Processing '$filename'";
        }
    }
};

sub MAIN ( *@filenames )
{
    process(@filenames)
}

我也有错误：

===SORRY!=== Error while compiling main.pm6
Undeclared routine:
    process used at line 14. Did you mean 'proceed'?

Answer 1

MAIN子需要在模块外声明，但仍然必须能够看到process。

有多种方法可以实现这一点，例如，不要声明一个模块

sub process(@filenames) {
    for @filenames -> $filename {
        say "Processing '$filename'";
    }
}

sub MAIN(*@filenames) {
    process(@filenames);
}

将process设为我们的范围并通过其长名称

调用它

module main {
    our sub process(@filenames) {
        for @filenames -> $filename {
            say "Processing '$filename'";
        }
    }
}

sub MAIN(*@filenames) {
    main::process(@filenames);
}

或导出process并将其导入MAIN

的正文中

module main {
    sub process(@filenames) is export {
        for @filenames -> $filename {
            say "Processing '$filename'";
        }
    }
}

sub MAIN(*@filenames) {
    import main;
    process(@filenames);
}

在我看来，最合适的选择是将MAIN添加到模块并将其导入脚本的主线。这样，模块中声明的所有内容都在MAIN中可见，而无需显式导出所有内容：

module main {
    sub process(@filenames) {
        for @filenames -> $filename {
            say "Processing '$filename'";
        }
    }

    sub MAIN(*@filenames) is export(:MAIN) {
        process(@filenames);
    }
}

import main :MAIN;

请注意，默认情况下，这不会导出MAIN，即模块的用户只有在提供:MAIN标记时才能获取。

如何在Perl6中制作modulino？

UPDATE：

1 个答案: