Question

我试图编写一个XSLT样式表来处理作者的姓名并格式化这些样式表，如Google学者搜索结果所示。

enter image description here

我的目标是遵循上面图像（突出显示）中显示的名称格式，例如我有这个xml：

    <names>
        <author>Naylor, Rosamond L.</author>
        <author>Goldburg, Rebecca J.</author>
        <author>Primavera, Jurgenne H.</author>
        <author>Kautsky, Nils</author>
    </names>

给定的名字并不总是＆＃34;姓氏，名字MI。＆＃34;格式，它也可以只是姓氏和首字母，如下所示：

    <names>
        <author>Naylor, R.L.</author>
        <author>Goldburg, R. J.</author>
        <author>Primavera, J.H.</author>
        <author>Kautsky, Nils</author>
    </names>

如果你问我到目前为止我尝试了什么，我会将其作为更新发布。我还在修改我在很久以前在SO上发布的question代码所用的代码。

提前致谢。

Answer 1

假设：

<强> XML

<names>
    <author>Naylor, R.L.</author>
    <author>Goldburg, R. J.</author>
    <author>Primavera, J.H.</author>
    <author>Kautsky, Nils</author>
</names>

以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:variable name="upper-case" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

<xsl:template match="names">
        <xsl:for-each select="author">
            <xsl:variable name="first-names" select="substring-after(., ', ')" />
            <xsl:value-of select="translate($first-names, translate($first-names, $upper-case, ''), '')"/>
            <xsl:text> </xsl:text>
            <xsl:value-of select="substring-before(., ', ')" />
            <xsl:if test="position()!=last()">
                <xsl:text>, </xsl:text>
            </xsl:if>
        </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

将返回：

RL Naylor, RJ Goldburg, JH Primavera, N Kautsky

警告：

XSLT 1.0中没有大写（）函数。上述方法仅适用于显式枚举的大写字符。如果文本包含其他文本（例如带有变音符号的字符），则会失败。

如果这是一个问题，最好使用类似的东西：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:str="http://exslt.org/strings">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="names">
        <xsl:for-each select="author">          
            <xsl:for-each select="str:tokenize(substring-after(., ', '),' .')">
                <xsl:value-of select="substring(., 1, 1)" />
            </xsl:for-each>
            <xsl:text> </xsl:text>
            <xsl:value-of select="substring-before(., ', ')" />
            <xsl:if test="position()!=last()">
                <xsl:text>, </xsl:text>
            </xsl:if>
        </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

假设您的处理器支持EXSLT str：tokenize（）函数（如果没有，则必须调用命名的递归模板来进行标记化）。

使用xslt解析名称

1 个答案: