Question

我们说我有这样的意见：

> [[0.8681299566762923,-0.3472589826095631], [3.2300860990307445,3.3731249077464946]]

如何将其转换为更令人愉快的类型，如Matrix（了解尺寸）？

Answer 1

您可以使用splatting（...）和hcat来获取您所追求的内容：

julia> a = Vector[[0.8681299566762923,-0.3472589826095631], [3.2300860990307445,3.3731249077464946]]
2-element Array{Array{T,1},1}:
 [0.8681299566762923,-0.3472589826095631]
 [3.2300860990307445,3.3731249077464946]

julia> hcat(a...)
2x2 Array{Float64,2}:
  0.86813   3.23009
 -0.347259  3.37312

或者，如果您希望将堆栈作为行而不是列，则可以执行以下操作：

julia> vcat(map(x->x', a)...)
2x2 Array{Float64,2}:
 0.86813  -0.347259
 3.23009   3.37312

我不建议逐行构建Matrix，因为这与Julia的column major array layout相冲突。对于较大的矩阵，实际上堆叠为列并转置输出效率更高：

julia> a2 = Vector{Float64}[rand(10) for i=1:5000];

julia> stackrows1{T}(a::Vector{Vector{T}}) = vcat(map(transpose, a)...)::Matrix{T}
stackrows1 (generic function with 2 methods)

julia> stackrows2{T}(a::Vector{Vector{T}}) = hcat(a...)'::Matrix{T}
stackrows2 (generic function with 2 methods)

julia> stackrows1(a2) == stackrows2(a2)  # run once to compile and make sure functions do the same thing
true

julia> @time for i=1:100 stackrows1(a2); end
elapsed time: 0.142792896 seconds (149 MB allocated, 7.85% gc time in 7 pauses with 0 full sweep)

julia> @time for i=1:100 stackrows2(a2); end
elapsed time: 0.05213114 seconds (88 MB allocated, 12.60% gc time in 4 pauses with 0 full sweep)

Answer 2

对于在大多数情况下都能正常工作的一般功能，如果出现问题则抛出错误，并允许您选择输出矩阵的形状，我很难想出比这更聪明的东西。以下（不可否认看起来不优雅）的解决方案：

function toMatrix{T<:Any}(x::Vector{Vector{T}}, dim::Int=1)
    if length(x) == 0
        return(Array(T, 0, 0))
    else
        N = length(x[1])
        M = length(x)
        if dim == 1
            xMat = Array(T, N, M)
            for m = 1:M
                if length(x[m]) != N
                    error("Conversion not possible due to vector length mismatch")
                end
                for n = 1:N
                    xMat[n, m] = x[m][n]
                end
            end
        elseif dim == 2
            xMat = Array(T, M, N)
            for m = 1:M
                if length(x[m]) != N
                    error("Conversion not possible due to vector length mismatch")
                end
                for n = 1:N
                    xMat[m, n] = x[m][n]
                end
            end         
        else
            error("Invalid dimension argument")
        end
        return(xMat)
    end
end

我有兴趣了解其他用户可以提出哪些解决方案。我当然不知道Base中的一项功能可以帮助你完成你的工作......

如何在Julia中将Array {Array {Float64,1}}，1}转换为Matrix？

2 个答案: