Question

我正试图在Coq中证明"Practical Coinduction"中的第一个例子。第一个例子是证明无限整数流上的词典排序是可传递的。

到目前为止，这是我的发展。首先只是无限流的通常定义。然后定义称为lex的词典顺序。最后是传递性定理的失败证明。

Require Import Omega.

Section stream.
  Variable A:Set.

  CoInductive Stream : Set :=
  | Cons : A -> Stream -> Stream.

  Definition head (s : Stream) :=
    match s with Cons a s' => a end.

  Definition tail (s : Stream) :=
    match s with Cons a s' => s' end.

  Lemma cons_ht: forall s, Cons (head s) (tail s) = s.
    intros. destruct s. reflexivity. Qed.

End stream.

Implicit Arguments Cons [A].
Implicit Arguments head [A].
Implicit Arguments tail [A].
Implicit Arguments cons_ht [A].

CoInductive lex s1 s2 : Prop :=
  is_le :   head s1 <= head s2 ->
            (head s1 = head s2 -> lex (tail s1) (tail s2)) ->
            lex s1 s2.


Lemma lex_helper: forall s1 s2,  
        head s1 = head s2 -> 
        lex (Cons (head s1) (tail s1)) (Cons (head s2) (tail s2)) -> 
        lex (tail s1) (tail s2).
Proof. intros; inversion H0; auto. Qed.

这是我要证明的引理。我首先准备目标，以便我可以应用构造函数，希望最终能够使用cofix中的“假设”。

Lemma lex_lemma : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
  intros s1 s2 s3 lex12 lex23.
  cofix.
  rewrite  <- (cons_ht s1).
  rewrite  <- (cons_ht s3).
  assert (head s1 <= head s3) by (inversion lex12; inversion lex23; omega).
  apply is_le; auto.

  simpl; intros. inversion lex12; inversion lex23.
  assert (head s2 = head s1) by omega.

  rewrite <- H0, H5 in *.
  assert (lex (tail s1) (tail s2)) by (auto).
  assert (lex (tail s2) (tail s3)) by (auto).

  apply lex_helper.
  auto.
  repeat rewrite cons_ht.
  Guarded.

我如何从这里开始？谢谢你的任何提示！

修改

感谢Arthur（一如既往！）有用且有启发性的答案，我也可以完成证明。我在下面提供我的版本以供参考。

Lemma lex_lemma : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
  cofix.
  intros s1 s2 s3 lex12 lex23.
  inversion lex12; inversion lex23.
  rewrite  <- (cons_ht s1).
  rewrite  <- (cons_ht s3).
  constructor; simpl.
  inversion lex12; inversion lex23; omega.
  intros; eapply lex_lemma; [apply H0 | apply H2]; omega.
Qed.

我使用cons_ht引理来“扩展”s1和s3的值。这里lex的定义（head和tail）更接近于Practical Coinduction中的逐字表述。 Arthur使用更优雅的技术，使Coq自动扩展价值 - 更好！

Answer 1

您的证明的一个问题是，在cofix被引入之后，您拨打s1 s2 s3的时间太晚了。因此，您得到的同感假设lex s1 s2并不是非常有用：为了在保持警惕的情况下应用它，正如您所提到的，我们需要在申请之后 lex的构造函数。但是，在这样做之后，我们需要在某些时候显示lex (tail s1) (tail s3)成立，cofix引入的假设无效。

为了解决这个问题，我们需要在引入变量之前执行对cofix 的调用，这样它产生的假设就足够了。我冒昧地重新定义了lex的定义，以便在这样的证明中操作变得更容易：

CoInductive lex : Stream nat -> Stream nat -> Prop := | le_head n1 n2 s1 s2 : n1 < n2 -> lex (Cons n1 s1) (Cons n2 s2) | le_tail n s1 s2 : lex s1 s2 -> lex (Cons n s1) (Cons n s2). Lemma lex_trans : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3. Proof. cofix. intros s1 s2 s3 lex12 lex23. inversion lex12; subst; clear lex12; inversion lex23; subst; clear lex23; try (apply le_head; omega). apply le_tail; eauto. Qed.

现在，假设的形式为

forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3
只要生成的应用程序受到保护，
就可以很容易地应用到我们的流的尾部。

在Coq中证明Co-Inductive属性（词汇顺序是传递的）

1 个答案: