Question

我在这里寻求proc转换问题的帮助。

我有一个这样的数据集（我只会显示3个变量，但我有很多变量）

PR  ID  VAR1a   VAR1b   VAR1c   VAR2a   VAR2b   VAR2c   VAR3a   VAR3b VAR3c 
1   1   x       x       x       x       x       x       x       x     x
1   2   x       x       x       x       x       x       x       x     x
1   3   x       x       x       x       x       x       x       x     x
2   1   x       x       x       x       x       x       x       x     x
2   2   x       x       x       x       x       x       x       x     x
2   3   x       x       x       x       x       x       x       x     x

我需要一个像这样的输出数据集：

PREID   ID  VAR(name)   A   B   C
1       1   VAR1(name)  x   x   x
1       1   VAR2(name)  x   x   x
1       1   VAR3(name)  x   x   x
1       2   VAR1(name)  x   x   x
1       2   VAR2(name)  x   x   x
1       2   VAR3(name)  x   x   x
1       3   VAR1(name)  x   x   x
1       3   VAR2(name)  x   x   x
1       3   VAR3(name)  x   x   x

等，preid 2 id 1 2 3，preid 3 id 1 2 3。

所以我需要转置，但使用名称（区别于b c），我真的不知道从哪里开始。你能帮帮我吗？

Answer 1

如果我能够正确理解输出。我认为要实现这一结果，首先对输入数据的每次观察都会分成几个不同的观察结果。因此，单个观察将转换为9（var1a到var3c）观察（您可以通过pr＆amp; id变量使用proc转置并将var1a转换为var3c变量）。在使用datastep之后，您需要将_NAME__变量分解为var1 / 2/3和a / b / c。完成此操作后，您应该能够转置数据以实现结果。

我尝试根据您的输入数据写下代码。如果有帮助，请告诉我。

data input;
infile datalines dsd dlm=',' missover;
input PR    :$8. 
      ID    :$8.  
      VAR1a :$8.  
      VAR1b :$8.  
      VAR1c :$8.   
      VAR2a :$8.  
      VAR2b :$8.  
      VAR2c :$8.  
      VAR3a :$8.  
      VAR3b :$8. 
      VAR3c :$8.;
datalines4;
1,1,x,x,x,x,x,x,x,x,x
1,2,x,x,x,x,x,x,x,x,x
1,3,x,x,x,x,x,x,x,x,x
2,1,x,x,x,x,x,x,x,x,x
2,2,x,x,x,x,x,x,x,x,x
2,3,x,x,x,x,x,x,x,x,x
;;;;
run;
proc transpose data=input out=staging ;
by  pr id ;
var VAR1a--VAR3c;
run;

data staging;
    set staging;
    var=substrn(strip(_name_),1,length(strip(_name_))-1);
    dummy=substrn(strip(_name_),length(strip(_name_)),1);

    drop _name_;
run;
proc transpose data=staging out=final(drop=_name_);
    by pr id var;
    id dummy;
    var  col1;
run;

proc print data=final;run;

Answer 2

与上面的@sushil解决方案类似，但少了一步。由于您无论如何都必须进入数据步骤，因此您也可以在该步骤中转置数据。因此，在该解决方案中，组合了Proc Transpose / Data步骤。如果你有足够的变量我也会删除最后一个转置，但如果你有很多变量，这会更灵活。

data input;
infile datalines dsd dlm=',' missover;
input PR    :$8. 
      ID    :$8.  
      VAR1a :$8.  
      VAR1b :$8.  
      VAR1c :$8.   
      VAR2a :$8.  
      VAR2b :$8.  
      VAR2c :$8.  
      VAR3a :$8.  
      VAR3b :$8. 
      VAR3c :$8.;
datalines4;
1,1,x,x,x,x,x,x,x,x,x
1,2,x,x,x,x,x,x,x,x,x
1,3,x,x,x,x,x,x,x,x,x
2,1,x,x,x,x,x,x,x,x,x
2,2,x,x,x,x,x,x,x,x,x
2,3,x,x,x,x,x,x,x,x,x
;;;;
run;

data out1;
set input;
array vars(*) var1a--var3c;
do i=1 to dim(vars);
name=vname(vars(i));
varname=substr(name,1,length(name)-1);
group=substr(name,length(name));
value=vars(i);
output;
end;

drop var1a--var3c;
run;

proc transpose data=out1 out=out2;
by pr id varname;
id group;
var value;
run;

SAS使用名称的一部分进行转置

2 个答案: