Question

我正在尝试将一些C ++代码包装到Cython中，并且在尝试将类中的方法作为参数传递给函数时遇到了一些麻烦。

我不知道它是否更清楚，但是A类代表统计模型（因此myAMethod不仅使用传递的参数而且使用许多实例变量），而B有不同的方法来最小化传递的函数。

在C ++中我有这种风格： class A { public: double myAMethod(double*) }; class B { public: double myBMethod(A&, double (A::*f) (double*) }

所以我要做的是在Cython代码中使用A和B的实例。我在包装课程时没有遇到任何问题，但是当我尝试使用myBMethod时，我不知道如何传递类型为A::*myAMethod的指针

如果我这样做： myBMethod(ptrToAObj[0], &ptrToAObj.myAMethod)，然后Cython将这段代码编译成[...] &ptrToAObj->myAMethod [...]，我得到了人们对g ++的期望：

＆＃34; ISO C ++禁止使用绑定成员函数的地址来形成指向成员函数的指针。＆＃34;

但是如果我试着直接指向类方法，然后执行myBMethod(ptrToAObj[0], A.myAMethod)，那么Cython就不会编译并说出

myAMethod不是A的静态成员。

这几乎是我所能提升的。我可以在C ++级别工作并避免任何这些异步，但如果我能够以交互方式在Python（通过Cython）中使用A和B的实例，它将有助于我加快我的开发速度。任何帮助将非常感激，如果这个问题已经得到回答和/或可以参考，我会道歉 - 我搜索SO，Cython参考和史密斯＆＃34; Cython＆＃34;书和我没有发现这个主题贴。提前谢谢！

Answer 1

我有一个部分（如果可怕）的解决方案。我已经准备好相信那里有更好的方法，但我不知道。

在cpp_bit.hpp中：

class A { 
  public:
    double myAMethod(double*) { return 0.0; }
}; 

typedef double (A::*A_f_ptr)(double *);

class B {
 public:
   double myBMethod(A& a, A_f_ptr f) { 
     double x = 0.1;
     return (a.*f)(&x);
   }
};

A_f_ptr getAMethod() {
  return &A::myAMethod;
}

我已经给出了非常基本的实现功能，所以我可以检查真正明显的崩溃。我还创建了一个函数指针，它返回指向myAMethod的指针。您需要为每个要包装的方法执行此操作。

在py_bit.pyx

中

# distutils: language = c++

from cython.operator import dereference

cdef extern from "cpp_bit.hpp":
  cdef cppclass A:
    double myAMethod(double*)

  cdef cppclass A_f_ptr:
    pass

  cdef cppclass B:
    double myBMethod(A&, A_f_ptr)

  cdef A_f_ptr getAMethod()

cdef class PyA:
  cdef A* thisptr
  def __cinit__(self):
    self.thisptr = new A()
  def __dealloc__(self):
    del self.thisptr
  cpdef myAMethod(self,double[:] o):
    return self.thisptr.myAMethod(&o[0])

cdef class PyB:
  cdef B* thisptr
  def __cinit__(self):
    self.thisptr = new B()
  def __dealloc__(self):
    del self.thisptr
  cpdef myBMethod(self,PyA a):
    return self.thisptr.myBMethod(dereference(a.thisptr),getAMethod())

我无法弄清楚如何在Cython中输入成员函数指针，所以我创建了一个具有相同名称的空cppclass。这是有效的，因为cython似乎只是用它来进行类型检查而已，而且由于它包含了cpp_bit.hpp（它定义了它），你可以毫无问题地使用它。

所有我完成的任务是将成员函数指针指向c ++（在我调用的getAMethod中）。我不认为它完全令人满意，但它看起来可行，并且只是您想要访问的每个成员函数的一个简短的额外c ++函数。你可以把它放在哪里玩，以便更干净地封装它。

另一种未经测试的方法：（编辑：进一步认为这可能非常棘手！尝试自行承担风险！）

就个人而言，我很想改变c ++界面，以便将myBMethod定义为

double myBMethod(std::function<double (double*)>)

（因为大概你总是用它传递的A实例来调用它）。然后在c ++（11！）中使用lambda函数将A实例和函数包装在一起

b.myBMethod([&](double* d){ return a.myAMethod(d) };

然后可能需要一些非常复杂的Cython包装，我还没有考虑过，但应该可以将一个简单的double (double*)函数指针转换为c ++函数对象，所以使用它更直接。

您的实际设计也可能在我无法考虑的方面变得更加复杂，而且这种方法无论如何都不够灵活。

在Cython中传递有界方法作为参数

1 个答案: