Question

我有一种情况需要导入目录中的所有文件并附加它们。我的代码就是这个

local files : dir "C:\Users\xx" files "*.xls"

local n: word count `files'
tokenize ``files''

cd "C:\Users\xx"

forval  k =1/`n'{

foreach file in `files' {
    import excel "`file'", sheet("Time Sheet") clear

drop in 3

if `k' == 1 {
    di in red `k'
        save "C:\Users\xx\master.dta", replace
    }
    else {
    append using "C:\Users\xx\master.dta"
    }
    save "C:\Users\xx\master.dta", replace
}
}

然而，当我使用这段代码时，似乎运行了一个额外的循环（* forval k = 1 /`n'*）来创建重复的条目。我无法摆脱那些代码，因为我需要它用于append命令。我想知道是否有办法缓解这个问题。

Answer 1

双循环导致问题：

local files : dir "D:/Datos/rferrer/Desktop/statatemps" files "test*.xls"

cd "D:/Datos/rferrer/Desktop/statatemps"

local counter = 1
foreach file in `files' {

    import excel "`file'", sheet("Hoja1") firstrow clear

    if `counter' == 1 {
        di in red `counter'
        save "D:/Datos/rferrer/Desktop/statatemps/master.dta", replace
    }
    else {
        append using "D:/Datos/rferrer/Desktop/statatemps/master.dta"
        save "D:/Datos/rferrer/Desktop/statatemps/master.dta", replace
    }

    local counter = 0
}

list

您不使用tokenize创建的令牌，因此您可以删除它。

更短的将是：

clear
set more off

local pathdir "D:/Datos/rferrer/Desktop/statatemps"

local files : dir "`pathdir'" files "test*.xls"

save "`pathdir'/master.dta", emptyok replace
foreach file in `files' {

    import excel "`file'", sheet("Hoja1") firstrow clear
    append using "`pathdir'/master.dta"
    save "`pathdir'/master.dta", replace

}

list

如果由于某种原因你有“怪异”的文件名（并且因为它仍然是一个很好的阅读），你可能想要阅读help quotes。

Stata：循环和追加

1 个答案: