Question

我正在对以下xml进行MODS转换MODS。为了清晰起见，我大大简化了它：

<?xml version="1.0" encoding="UTF-8"?>
<OAI-PMH>
  <metadata>
    <mods>
      <genre>Negatives (photographic)</genre>
      <genre>Cellulose nitrate film</genre>
      <physicalDescription>
        <form>Photograph</form>
      </physicalDescription>
    </mods>
</metadata></OAI-PMH>

我需要这个结果，其中genre元素已经成为form元素，它们是已存在的physicalTransform元素的子元素：

<?xml version="1.0" encoding="UTF-8"?>
<OAI-PMH>
  <metadata>
    <mods>
      <physicalDescription>
        <form>Photograph</form>
        <form>Negatives (photographic)</form>
        <form>Cellulose nitrate film</form>
      </physicalDescription>
    </mods>
</metadata></OAI-PMH>

我该怎么做呢？我试过这个：

<xsl:template match="mods:physicalDescription">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
        <xsl:apply-templates select="mods:genre"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="mods:genre">
    <xsl:element namespace="http://www.loc.gov/mods/v3" name="form" >
        <xsl:value-of select="normalize-space(.)"/> 
    </xsl:element>  
</xsl:template>

但它不起作用。我确信我遗漏了一些简单的东西，但我无法确定是什么。任何帮助将不胜感激。谢谢。

Answer 1

您指的是命名空间，但未在输入XML中声明此命名空间。我假设它是一个默认命名空间：

XML输入

<?xml version="1.0" encoding="UTF-8"?>
<OAI-PMH xmlns="http://www.loc.gov/mods/v3">
  <metadata>
    <mods>
      <genre>Negatives (photographic)</genre>
      <genre>Cellulose nitrate film</genre>
      <physicalDescription>
        <form>Photograph</form>
      </physicalDescription>
    </mods>
</metadata>
</OAI-PMH>

在您发布的样式表中，您应删除不可见的空白字符。此外，应该有一种机制可以生成输入的忠实副本，您可以在此基础上定义更改 - 这称为身份模板。

然后，在mods:physicalDescription的模板匹配中，找到所有mods:genre元素作为兄弟元素，并在同一名称空间中为每个元素输出元素form。

添加与mods:genre匹配的最后一个模板，不再需要单独处理它们。

XSLT样式表

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
xmlns:mods="http://www.loc.gov/mods/v3"
exclude-result-prefixes="mods">

    <xsl:output method="xml" encoding="UTF-8" indent="yes" />
    <xsl:strip-space elements="*"/>

    <xsl:template match="mods:physicalDescription">
        <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
        <xsl:for-each select="../mods:genre">
            <form xmlns="http://www.loc.gov/mods/v3">
                <xsl:apply-templates select="@*|node()"/>
            </form>
        </xsl:for-each>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="mods:genre"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

</xsl:transform>

XML输出

正如您所看到的，除了您未包含的默认命名空间外，这会产生您所请求的输出。

<?xml version="1.0" encoding="UTF-8"?>
<OAI-PMH xmlns="http://www.loc.gov/mods/v3">
   <metadata>
      <mods>
         <physicalDescription>
            <form>Photograph</form>
            <form>Negatives (photographic)</form>
            <form>Cellulose nitrate film</form>
         </physicalDescription>
      </mods>
   </metadata>
</OAI-PMH>

使变形元素成为兄弟姐妹的孩子

1 个答案: