Question

我正在寻找Perl 5中的一个函数，它与Python的enumerate内置函数类似。它将返回一个对数组的引用列表，其中每个数组都是[$index, $element]：

@a = ("a", "b", "c");
@b = enumerate @a;
# @b = ([0, "a"], [1, "b"], [2, "c"])

List::Util和List::MoreUtils似乎没有此功能。还有另一个模块吗？

Answer 1

您可以使用map，就像这样

my @data = qw / a b c /;
my @enumeration = map [ $_, $data[$_] ], 0 .. $#data;

Answer 2

Perl没有这样做的内置功能，但它很容易推出自己的功能。

使用map：

my @a = qw(a b c);
my $i = 0;
my @b = map [$i++, $_], @a; # ([0, 'a'], [1, 'b'], [2, 'c'])

从v5.20开始，Perl的新切片语法做了类似的事情：

my @a = qw(a b c);
my @b = %a[0..$#a]; # (0, 'a', 1, 'b', 2, 'c')

该切片语法返回索引/值对列表，但它是一个平面列表。这些对不能分组为嵌套数组。如果这对您的应用程序很重要，您可以使用List :: Util中的pairmap函数来执行此操作：

use List::Util qw(pairmap);
my @a = qw(a b c);
my @b = pairmap {[$a, $b]} %a[0..$#a]; # ([0, 'a'], [1, 'b'], [2, 'c'])

Answer 3

enumerate返回一个迭代器，而不是一个列表，所以你应该真的要求一个迭代器。

在Perl 5.12.0及更高版本中，您可以使用each迭代数组：

use strict;
use warnings 'all';
use 5.012;

my @a = qw(foo bar baz);

while (my ($i, $v) = each @a) {
    say "$i -> $v";
}

__END__
0 -> foo
1 -> bar
2 -> baz

但是，使用each时应该非常小心; some people even discourage its use altogether

Answer 4

使用List::Enumerate模块。

use List::Enumerate qw(enumerate);
@a = ("a", "b", "c");
@b = map { [ $_->index, $_->item ] } enumerate(@a);

Answer 5

sub enumerate(&@) {
    local *f = shift;
    my @array = @_;
    my @ret;
    my $pkg = caller;
    for ( my $i = 0 ; $i < @array ; $i++ ) {
        no strict 'refs';
        local *{ $pkg . '::a' } = \$i;
        local *{ $pkg . '::b' } = \$array[$i];
        push @ret, f( $i, $array[$i] );
    }
    @ret;
}
my @tmp = enumerate { ($a, $b) } 'a'..'z';
say "@tmp";

什么是Perl相当于Python的枚举？

5 个答案: