Question

在我的扩展TComboBox类中，我覆盖了ComboWndProc()过程处理程序，但是我无法从列表的滚动条（FListHandle）中检测到CN_VSCROLL和WM_VSCROLL消息。

我基本上想要使用winapi实现无限滚动我想，为了做我想要的，我基本上需要知道滚动的轨迹栏位置，所以当轨迹栏触摸行向下按钮时，我会向字符串添加更多数据。

这个想法很简单，也许很幼稚，但我可以从那里开始，看看我会遇到什么问题。

有可能做这样的事吗？

有没有办法跟踪来自TComboBox的滚动条消息？

更重要的是：

如果是，如何？
如果不是，为什么？

Answer 1

您可以使用WM_VSCROLL这样做，您必须继承组合框的列表框控件。 CN_VSCROLL将无效，因为组合框的列表框部分不是VCL控件。

以下示例主要来自Kobik的this answer，为了完整起见，此处包含此内容。

type
  TForm1 = class(TForm)
    ComboBox1: TComboBox;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FComboListWnd: HWND;
    FComboListWndProc, FSaveComboListWndProc: Pointer;
    procedure ComboListWndProc(var Message: TMessage);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  Info: TComboBoxInfo;
begin
  ZeroMemory(@Info, SizeOf(Info));
  Info.cbSize := SizeOf(Info);
  GetComboBoxInfo(ComboBox1.Handle, Info);
  FComboListWnd := Info.hwndList;
  FComboListWndProc := classes.MakeObjectInstance(ComboListWndProc);
  FSaveComboListWndProc := Pointer(GetWindowLong(FComboListWnd, GWL_WNDPROC));
  SetWindowLong(FComboListWnd, GWL_WNDPROC, Longint(FComboListWndProc));
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  SetWindowLong(FComboListWnd, GWL_WNDPROC, Longint(FSaveComboListWndProc));
  classes.FreeObjectInstance(FComboListWndProc);
end;

procedure TForm1.ComboListWndProc(var Message: TMessage);
begin
  case Message.Msg of
    WM_VSCROLL: OutputDebugString('scrolling');
  end;
  Message.Result := CallWindowProc(FSaveComboListWndProc,
      FComboListWnd, Message.Msg, Message.WParam, Message.LParam);
end;

有没有办法跟踪TComboBox的滚动条消息？

1 个答案: