Question

我是erlang和ejabbered / mongooseIM的新手。我正在尝试编写一个非常简单的mongoose模块，它将在发送之前为数据包添加额外的子元素。以下是我的代码：

-module(mod_test).

-behavior(gen_mod).


-export([start/2, stop/1]).
-export([add_child/1]).

-include("ejabberd.hrl").

start(Host, Opts) ->
    ejabberd_hooks:add(filter_packet, Host, ?MODULE, add_child, 0),
    ?DEBUG(" MOD_TEST Started",[]),
    ok.

stop(Host) ->
    ejabberd_hooks:delete(filter_packet, Host, ?MODULE, add_child, 0),
    ok.

add_child({From, To, XML} = Packet) ->
    Tag = {"a","b"},
    NewPacket = xml:append_subtags(Packet, [Tag]),
    ?INFO_MSG("  To party: ~p~n",[To]),
    NewPacket.

我可以用很少的警告编译代码

mod_test.erl:3: Warning: behaviour gen_mod undefined
mod_test.erl:11: Warning: variable 'Opts' is unused
mod_test.erl:20: Warning: variable 'From' is unused
mod_test.erl:20: Warning: variable 'XML' is unused

然后，当我添加模块并运行它时，它会启动，但它不会对数据包进行任何更改，也不会生成任何日志。

另一个问题是，如果我在启动函数中添加一个日志，它会被编译但我在启动模块时看到错误

2015-03-03 16:36:34.772 [critical] <0.200.0>@gen_mod:start_module:94 Problem starting the module mod_test for host <<"localhost">>
 options: []
 error: undef
[{lager,info,["  mod_test starting ...",[[]]],[]},
 {mod_test,start,2,[{file,"mod_test.erl"},{line,13}]},
 {gen_mod,start_module,3,[{file,"src/gen_mod.erl"},{line,83}]},
 {lists,foreach,2,[{file,"lists.erl"},{line,1336}]},
 {ejabberd_app,start,2,[{file,"src/ejabberd_app.erl"},{line,69}]},
 {application_master,start_it_old,4,
                     [{file,"application_master.erl"},{line,272}]}]
2015-03-03 16:36:34.773 [critical] <0.200.0>@gen_mod:start_module:99 ejabberd initialization was aborted because a module start failed.
The trace is [{lager,info,["  mod_test starting ...",[[]]],[]},{mod_test,start,2,[{file,"mod_test.erl"},{line,13}]},{gen_mod,start_module,3,[{file,"src/gen_mod.erl"},{line,83}]},{lists,foreach,2,[{file,"lists.erl"},{line,1336}]},{ejabberd_app,start,2,[{file,"src/ejabberd_app.erl"},{line,69}]},{application_master,start_it_old,4,[{file,"application_master.erl"},{line,272}]}].

Crash dump was written to: erl_crash.dump
Problem starting the module mod_test for host <<"localhost">>
 options: []
 error: undef
[{lager,info,["  mod_xyz starting ...",[[]]],[]},
 {mod_test,start,2,[{file,"mod_timetagg

我做错了什么？

Answer 1

所以你的例子实际上有点棘手，因为filter_packet钩子的工作原理。您在第一次尝试时选择了最差的钩子注册;）

如果您查看ejabberd_router:do_route，您会看到filter_packet在没有Host参数的情况下运行 - 它是一个全局挂钩，所以当您注册add_child时对于特定Host的函数，它基本上会被忽略。

尝试以下方法：

-module(mod_test).
-behavior(gen_mod).

-export([start/2, stop/1]).
-export([add_child/1]).

-include_lib("ejabberd/include/ejabberd.hrl").
-include_lib("exml/include/exml.hrl").

start(Host, Opts) ->
    ejabberd_loglevel:set_custom(?MODULE, 5),
    ejabberd_hooks:add(filter_local_packet, Host, ?MODULE, add_child, 1),
    ?DEBUG(" MOD_TEST Started",[]),
    ok.

stop(Host) ->
    ejabberd_hooks:delete(filter_local_packet, Host, ?MODULE, add_child, 1),
    ok.

add_child({From, To, Element} = HookData) ->
    ?DEBUG("Filtering ~p~n", [HookData]),
    case Element#xmlel.name of
        <<"message">> ->
            Tag = #xmlel{name = <<"added-tag">>, attrs = [], children = []},
            NewElement = xml:append_subtags(Element, [Tag]),
            ?DEBUG("will return new el: ~p", [NewElement]),
            {From, To, NewElement};
        _ ->
            ?DEBUG("will pass old el: ~p", [Element]),
            HookData
    end.

现在可以在您给定的filter_local_packet上注册Host，并且所有传入的节都将传递给您的函数。重要的是要记住，向所有节添加虚假标签可能会破坏内容，因此上述代码只会向<added-tag>节添加<message>元素。

使用上面的示例并从那里开始工作。

祝你好运！

Answer 2

错误是undef，这意味着调用了一个未定义/导出的函数。 stacktrace显示有问题的函数是lager:info/2。

Lager（处理你的?INFO_MSG的日志库）有一个特殊的怪癖，你的代码会调用不存在的函数，但代码在编译之前通过解析转换进行转换。看起来这并没有发生在你身上。

MongooseIM树中rebar.config中的apps/ejabberd文件在{parse_transform, lager_transform}中包含erl_opts，要求编译器应用解析变换。我建议将mod_test.erl放入apps/ejabberd/src并构建整个MongooseIM树;这将确保您的文件使用正确的选项构建。

MongooseIM简单模块事件未得到处理

2 个答案: