Question

我需要通过在新组元素下对相关元素进行分组，将下面的代码段更改为层次结构。 XSLT听起来像是在这里使用的适当技术，但我不太了解它以评估它是否能够满足我的需求。一个示例分组标准是＆＃34; 1＆＃39; d＆＃39;节点后跟一些＆＃39; 3＆＃39;节点，然后是1＆＃39; f＆＃39;节点＆＃34 ;.我必须针对几个单独的标准执行此任务，因此我想知道在XSLT中是否可以进行这种性质的查询，或者我是否可以更好地放弃并在程序上放弃和处理DOM。我也完全接受其他策略。对于一个具体的例子，我需要转换它 -

<root>
    <a>foo</a>
    <b>bar</b>
    <c>baz</c>
    <d>location</d>
    <e>3.14</e>
    <e>6.02</e>
    <e>1.23</e>
    <f>2015</f>
    <d>location</d>
    <e>3.14</e>
    <e>6.02</e>
    <f>2015</f>
</root>

进入 -

<root>
    <a>foo</a>
    <b>bar</b>
    <c>baz</c>
    <sample>
        <d>location</d>
        <e>3.14</e>
        <e>6.02</e>
        <e>1.23</e>
        <f>2015</f>
    </sample>
    <sample>
        <d>location</d>
        <e>3.14</e>
        <e>6.02</e>
        <f>2015</f>
    </sample>
</root>

Answer 1

如果您要对元素进行分组，从d开始，您可以使用以下方法。的 XSLT-1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> <xsl:output indent="yes" method="xml" /> <xsl:strip-space elements="*"/>  <xsl:key name="following" match="e | f" use="generate-id(preceding::d[1])"/>  <xsl:template match="@* | node()"> <xsl:copy> <xsl:apply-templates select="@* | node()"/> </xsl:copy> </xsl:template>  <xsl:template match="d"> <sample> <xsl:copy-of select="current() | key('following', generate-id())"/> </sample> </xsl:template>  <xsl:template match="e|f"/> </xsl:stylesheet>

当然，XSLT并不局限于这种简单的分组。

Answer 2

这是我对方法的看法，因为我通常在XSLT 1.0环境中工作。

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml"/>

    <!-- any nodes that I don't address specifically, I copy -->
    <xsl:template match="*">
        <xsl:copy-of select="."/>
    </xsl:template>

    <!-- from the root, deal with a, b, c, d nodes -->
    <xsl:template match="root">
        <root>
            <xsl:apply-templates select="a|b|c|d"/>
        </root>
    </xsl:template>

    <!-- the d node is the fun one -->
    <xsl:template match="d">
        <!-- add the wrapper -->
        <sample>
            <!-- first, copy the d node -->
            <xsl:copy-of select="."/>
            <!--
            process any following sibling e nodes if that
            e node's immediately preceding d sibling is the
            "current" node - i.e. the d node that got us here

            We use the fact that in XSLT 1.0, a union of nodes
            will never contain duplicates, so if the count is
            one, that means the two parts of the union are the
            same node
            -->
            <xsl:apply-templates select="following-sibling::e
                [count(current() | preceding-sibling::d[1]) = 1]"/>
            <!-- same logic for f nodes -->
            <xsl:apply-templates select="following-sibling::f
                [count(current() | preceding-sibling::d[1]) = 1]"/>
        </sample>
    </xsl:template>
</xsl:stylesheet>

现在，我认为，这是否令你信服XSLT是正确的工具，或者让你尖叫恐怖取决于你的个性，我猜想。

XSLT分组的限制？

2 个答案: