Question

我们说我有一个包规格。存储常量值，这些值在其他包（主要是它们的程序）中广泛使用 - 所以像自定义错误消息，特定值，甚至像

这样的列表

TYPE myTableType IS TABLE OF VARCHAR2(100); myObj mytype := NEW myTableType ('value1','value2')

但我现在想添加一个完整的＆＃34;字典＆＃34;现在的结构 - 所以一个关键列表 - ＆gt;该包中的价值对。

似乎我无法初始化该部分中的记录表，如下所述： https://asktom.oracle.com/pls/asktom/f?p=100:11%3A0%3A%3A%3A%3AP11_QUESTION_ID:14334298866128 而且似乎链接中提到的对象表也不是我的解决方案。不确定什么是某种最好的解决方法。

有什么想法吗？

Answer 1

给出包规范

CREATE OR REPLACE PACKAGE example IS

   TYPE assoc_array_type IS TABLE OF VARCHAR2(100) INDEX BY VARCHAR2(100);

   g_const_array assoc_array_type;

   PROCEDURE dummy_proc (i_var NUMBER);
END example;
/

您可以按如下方式初始化常量的关联数组

CREATE OR REPLACE PACKAGE BODY example IS

   PROCEDURE dummy_proc (i_var NUMBER) IS
   BEGIN
      dbms_output.put_line(g_const_array('key_1'));
   END dummy_proc;

BEGIN
   g_const_array('key_1') := 'value_1';
   g_const_array('key_2') := 'value_2';
   g_const_array('key_3') := 'value_3';
END example;
/

要测试，编译spec和body，然后调用dummy_proc，它将value_1打印到控制台。对于不同的需要，关联数组也可以由binary_integer或pls_integer索引。

编辑：第二个包显示您可以引用公共数组并从其他包中的初始化中获取值。

CREATE OR REPLACE PACKAGE example_2 IS

   PROCEDURE dummy_proc (i_key VARCHAR2);

END example_2;
/

CREATE OR REPLACE PACKAGE BODY example_2 IS

   PROCEDURE dummy_proc (i_key VARCHAR2) IS
   BEGIN
      dbms_output.put_line(example.g_const_array(i_key));
   END dummy_proc;

END example_2;
/

BEGIN
   example_2.dummy_proc('key_1');
END;
/

在oracle包规范中创建一个类似字典的值集合

1 个答案: