Question

我是Perl的新手，正在尝试使用XML::Twig模块对XML文件应用过滤条件。

以下是我的代码：

#!/usr/bin/perl
use strict;
use warnings;

use XML::Twig;

my $SOURCEFILE     = $ARGV[0];
my $FILELOCATIONIN = $ARGV[1];

my $twig = new XML::Twig( twig_handlers => { 'STOCKEXT/STOCK' => \&STOCK } );

$twig->parsefile($FILELOCATIONIN.'/'.$SOURCEFILE.'.xml');

$twig->set_pretty_print('indented');

$twig->print_to_file($FILELOCATIONIN.'/'.$SOURCEFILE.'out.xml');

sub TRADE {
    my ( $twig, $STOCK ) = @_;
    foreach  my $c ($STOCK)
        {
         $c->delete($STOCK)
         unless
         $c->att('origin') eq "HIGH_TRADE"

      ;
    }
}

以下是我的XML：

<STOCKEXT>
  <STOCK origin = "HIGH_TRADE"/>
  <STOCK origin = "HIGH_TRADE"/>
  <STOCK origin = "HIGH_TRADE"/>
  <STOCK origin = "LOW_TRADE"/>
  <STOCK origin = "LOW_TRADE"/>
  <STOCK origin = "AVERAGE_TRADE"/>
</STOCKEXT>

过滤输出XML：

<STOCKEXT>
  <STOCK origin = "HIGH_TRADE"/>
  <STOCK origin = "HIGH_TRADE"/>
  <STOCK origin = "HIGH_TRADE"/>
</STOCKEXT>

现在我被卡住了，因为我想在命令行中传递以逗号分隔的参数，以便HIGH_TRADE和AVERAGE_TRADE成为合法STOCK。

可以看出，在我当前的代码中，我传递了两个参数。但我想传递三个参数，第三个应该是以逗号分隔格式的过滤条件。

因此，我希望我的代码可以作为

调用

perl stock_filter.pl file_name.xml /opt/XML HIGH_TRADE,AVERAGE_TRADE

第三个参数将被拆分并根据每个origin元素的STOCK属性进行检查，以声明它是合法的。

这有助于将来更改过滤条件。过滤条件的任何加法或减法都不会改变代码。

Answer 1

对我来说最明显的解决方案是使用List::Util模块中的any函数。

这是您自己的代码版本，其中包含一些其他修改。最重要的是，我使用了File::Spec::Functions模块中的catfile函数来更安全地组合路径和文件名。

use strict;
use warnings;
use 5.014;    # For non-destructive substitution

use XML::Twig;
use File::Spec::Functions 'catfile';
use List::Util 'any';

my ($source_file, $file_location, $stock_origins) = @ARGV;

my $twig = XML::Twig->new(
    twig_handlers => { 'STOCKEXT/STOCK' => \&stock_handler },
    pretty_print  => 'indented',
);

my $full_input    = catfile($file_location, $source_file);
my @stock_origins = split /,/, $stock_origins;
my $full_output   = $full_input =~ s/(?=\.[^.]+\z)/_out/r;

$twig->parsefile($full_input);
$twig->print_to_file($full_output);

sub stock_handler {
  my ( $twig, $stock ) = @_;
  my $origin = $stock->att('origin');

  $stock->delete unless any { $origin eq $_ } @stock_origins;
}

<强>输出

<STOCKEXT>
  <STOCK origin="HIGH_TRADE"/>
  <STOCK origin="HIGH_TRADE"/>
  <STOCK origin="HIGH_TRADE"/>
  <STOCK origin="AVERAGE_TRADE"/>
</STOCKEXT>

Answer 2

执行此操作的一种方法是将要保留的值存储在哈希值中。

在脚本顶部创建哈希：

my @origins_to_keep= split /,/, $ARGV[2];
my %keep= map { $_ => 1 } @origins_to_keep;

在处理程序中使用它：

$c->delete($STOCK) unless $keep{$c->att('origin')}

如何通过从命令行传递参数在Perl中应用IN子句

2 个答案: