使用gnuplot，如何删除＆＃39; us使用图的y轴区域

Question

我正在尝试绘制图表，在Y轴上我有CPU利用率，当前范围是0-100％。我的数据仅包括0-20％和80-100％，我只有20-80％的大白差距。有没有办法'剪掉'这个空白区域，所以观众可以更详细地看到0-20％和80-100％范围内的情况？

谢谢。

Answer 1

正如Christoph在评论中所说，这需要使用set multiplot手动完成并删除边框等。例如：

set multiplot
# remove border and ytics from right hand side
set border 7
set ytics nomirror
# set top and bottom margins for both halves of the plot
set tmargin at screen 0.96
set bmargin at screen 0.1
# set left and right margins for left half of the plot
set lmargin at screen 0.1
set rmargin at screen 0.5
# set xrange for left half of the plot
set xrange [0:2*pi]
# set some lines to delimit transition from one half of the plot to next
set arrow from screen 0.50,0.08 to screen 0.52,0.12 nohead
set arrow from screen 0.49,0.08 to screen 0.51,0.12 nohead
set arrow from screen 0.50,0.94 to screen 0.52,0.98 nohead
set arrow from screen 0.49,0.94 to screen 0.51,0.98 nohead
# plot left half
plot sin(x) not
# remove border from left hand side and set ytics on the right
set border 13
unset ytics
set y2tics
set format y2 ""
# set left and right margins for right half of the plot
set lmargin at screen 0.51
set rmargin at screen 0.91
# set xrange for right half of the plot
set xrange [13.5:13.5+2*pi]
# plot
plot sin(x) axes x1y2