Question

我想创建一个excel工作簿，可以将工作表上的单元格范围转换为另一张工作表上的图片，并且如果源表上有任何修改，则能够自动更新图片。我没有宏背景。

Answer 1

这是一个你可以适应的例子。我们希望捕获范围 C3：F10

的更改

这些是输入变化而不是计算结果。

如果更改了此块中的单元格，则该块将被复制为图片，并且 Sheet3 中的图片将复制到单元格 C5

附近

在工作表代码区域中插入以下事件宏：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim r1 As Range, r2 As Range, sv As Range
    Dim sh As Worksheet
    Set r1 = Range("C3:F10")
    Set r2 = Sheets("Sheet3").Range("C5")

    If Intersect(Target, r1) Is Nothing Then Exit Sub

    Set sv = Selection
    Set sh = ActiveSheet

    Application.EnableEvents = False
        r1.CopyPicture Appearance:=xlScreen, Format:=xlPicture
        Sheets("Sheet3").Select
        On Error Resume Next
            ActiveSheet.Shapes("Latest Snap").Delete
        On Error GoTo 0
        r2.Select
        ActiveSheet.Paste
        Selection.Name = "Latest Snap"
        sh.Select
        sv.Select
    Application.EnableEvents = True
End Sub

因为它是工作表代码，所以很容易安装和自动使用：

右键单击Excel窗口底部附近的选项卡名称
选择查看代码 - 这会打开一个VBE窗口
粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。如果您在2003年之后使用的是Excel版本，则必须保存该文件为.xlsm而不是.xlsx

删除宏：

按上述方式调出VBE窗口
清除代码
关闭VBE窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其生效！

excel自动将单元格范围转换为另一张纸上的图片并自动更新

1 个答案: