Question

使用Oracle 11.2

您好，

这是我想要做的：我使用dbms_scheduler安排作业。要安排的作业数量不固定，最多可以同时运行4个作业。安排作业的过程应该等到所有作业完成。如果一个工作失败，那么＆＃34;计划＆＃34;过程也应该失败，并且应该从调度程序中删除所有剩余的预定作业。

目前我不得不在一个循环中休眠和轮询表user_scheduler_jobs。

我是PL / SQL的新手而且缺乏经验，所以请不要对我太苛刻;）

到目前为止，这是我的代码。

首先是用于安排作业的代码段：

BEGIN
  FOR r IN (SELECT p_values FROM some_table WHERE flag = 0 )
  LOOP
    --  count running jobs
    SELECT count(*) INTO v_cnt
    FROM user_scheduler_jobs
    WHERE job_name LIKE 'something%';

    /*
    If max number of parallel jobs is reached, then wait before starting a new one.
    */
    WHILE v_cnt >= l_max_parallel_jobs
    LOOP

      dbms_lock.sleep(10);

      SELECT count(*) INTO v_cnt
      FROM user_scheduler_jobs
      WHERE job_name LIKE 'something%' AND state = 'RUNNING';

      SELECT count(*) INTO v_cnt_failures
      FROM user_scheduler_jobs
      WHERE job_name LIKE 'something%' AND state = 'FAILED' OR state = 'BROKEN';

      IF v_cnt_failures > 0 THEN RAISE some_exception; END IF;

    END LOOP;

    -- Start a new Job
    v_job_name := 'something_someting_' || p_values;
    v_job_action := 'begin user.some_procedure(''' || r.p_values || '''); end;';

    dbms_scheduler.create_job(job_name   => v_job_name,
                              job_type   => 'PLSQL_BLOCK',
                              job_action => v_job_action,
                              comments   => 'Some comment ' || v_job_name,
                              enabled    => FALSE,
                              auto_drop  => FALSE);

    dbms_scheduler.set_attribute(NAME => v_job_name,
                                 ATTRIBUTE => 'max_failures',
                                 VALUE => '1');

    dbms_scheduler.set_attribute(NAME => v_job_name,
                                 ATTRIBUTE => 'max_runs',
                                 VALUE => '1');

    dbms_scheduler.enable(v_job_name);

    v_job_count := v_job_count + 1;

    -- array for all jobs
    v_jobs_aat(v_job_count) := v_job_name;

  END LOOP;

  -- ... Wait till all jobs have finisched. 

  check_queue_completion(v_jobs_aat); -- see procedure below
END;

等待最后四个工作完成的程序：

PROCEDURE check_queue_completion(p_jobs_aat IN OUT t_jobs_aat) AS
  v_state user_scheduler_jobs.state%TYPE;
  v_index PLS_INTEGER;
  v_done BOOLEAN := TRUE;

  -- Exceptions
  e_job_failure EXCEPTION;
BEGIN

  WHILE v_done
  LOOP

    v_done := FALSE;

    FOR i IN p_jobs_aat.first..p_jobs_aat.last
    LOOP

      SELECT state INTO v_state FROM user_scheduler_jobs WHERE job_name = p_jobs_aat(i);

      --dbms_output.put_line('Status: ' || v_state);

      CASE

        WHEN v_state = 'SUCCEEDED' OR v_state = 'COMPLETED' THEN
        dbms_output.put_line(p_jobs_aat(i) || ' SUCCEEDED');
        dbms_scheduler.drop_job(job_name => p_jobs_aat(i), force => TRUE);
        p_jobs_aat.delete(i);

        WHEN v_state = 'FAILED' OR v_state = 'BROKEN' THEN
        --Exception auslösen
        dbms_output.put_line(p_jobs_aat(i) || ' FAILED');
        RAISE e_job_failure;

        WHEN v_state = 'RUNNING' OR v_state = 'RETRY SCHEDULED' THEN
        NULL;
        dbms_output.put_line(p_jobs_aat(i) || ' RUNNING or RETRY SCHEDULED');
        v_done := TRUE;

      /*DISABLED, SCHEDULED, REMOTE, CHAIN_STALLED*/
      ELSE
        dbms_output.put_line(p_jobs_aat(i) || ' ELSE');
        dbms_scheduler.drop_job(job_name => p_jobs_aat(i), force => TRUE);
        p_jobs_aat.delete(i);
      END CASE;

    END LOOP;

    hifa.gen_sleep(30);

  END LOOP;

  IF p_jobs_aat.count > 0 THEN delete_jobs_in_queue(p_jobs_aat); END IF;

  EXCEPTION WHEN e_job_failure THEN
  delete_jobs_in_queue(p_jobs_aat);
  RAISE_APPLICATION_ERROR(-20500, 'some error message');

END check_queue_completion;

它可以解决这个问题，但它似乎有些糟糕。

不是有更好的方法：

等到所有工作完成。
一次只运行四个作业，并在其中一个正在运行的作业完成后立即开始新作业。
如果一个作业失败或被破坏，则抛出异常。

Answer 1

DECLARE
  cnt NUMBER:=1;
BEGIN
  WHILE cnt>=1
  LOOP
    SELECT count(1) INTO cnt FROM dba_scheduler_running_jobs srj
    WHERE srj.job_name IN ('TEST_JOB1','TEST_JOB2');
    IF cnt>0 THEN
      dbms_lock.sleep (5);
    END IF;
  END LOOP;
  dbms_output.put_line('ASASA');  
END;

Answer 2

使用dbms_alert或dbms_pipe发送/接收有关作业开始/结束的信息。仅当您未在预期时间内收到信息时才查询作业表。

Answer 3

Oracle Scheduler大量使用Oracle Rersource Manager，只需提交您的作业，使用结束通知定义，并有一个任务等待您的事件Q，它会计算已提交的作业和已完成的作业。

您使用Oracle Resource Manager来控制要并发运行的最大作业数。这也将基于总数据库负载，再次保护其他用户被作业淹没的系统。

如何等待dbms_scheduler作业完成

3 个答案: