如何使用DigitalMicrograph脚本同步外部应用程序？

Question

  

这个问题的灵感来自问题'Call script from command line'。

如何编写一个脚本来触发事件＆＃39;在应用程序其他而不是DigitalMicrograph？

即。某些脚本功能应该由外部应用程序触发。

Answer 1

脚本语言在当前状态下不提供许多“外部”接口。可以使用命令LaunchExternalProcess 调出到外部进程并等待进程完成，但外部进程没有直接的方法来调用在中，即在DigitalMicrograph中启动脚本操作。

但是，可以通过将系统的文件系统用作消息队列来解决该问题。要执行此操作，请在后台运行一个脚本，定期检查某个文件是否存在，并让外部应用程序在想要在DigitalMicrograph中触发脚本操作时创建此类文件。文件内容 - 如果是简单的文本文件 - 也可用于在两个应用程序之间传输信息。

这是一个示例脚本，它将等待文件Trigger.txt出现在根文件夹中。检查每10秒执行一次。

class WaitForExternal
{
    string triggerFilePath
    number taskID
    void WaitOnTrigger( object self )
    {
        if ( DoesFileExist( triggerFilePath ) )
        {
            Result( GetTime(1) + ": Triggered! Now act..." )
            If ( TwoButtonDialog( "Do you want to reset the trigger?", "Reset", "Stop" ) )
            {
                DeleteFile( triggerFilePath )
            }
            else
            {
                RemoveMainThreadTask( taskID )
            }
        }
        else
        {
            Result( GetTime(1) + ": not yet\n" )
        }
    }

    object Init( object self, string triggerPath, number waitSec ) 
    { 
        triggerFilePath = triggerPath
        taskID = self.AddMainThreadPeriodicTask( "WaitOnTrigger", waitSec )
        return self
    }
}

// Main script
{
    string triggerPath = "C:\\Trigger.txt"
    number pollingWait = 10
    Alloc(WaitForExternal).Init( triggerPath, pollingWait )
}

请注意，周期性任务在后台等待空闲而不会干扰CPU，但实际检查将在主线程上执行。