Question

我有一个函数将文档转换为不同的格式，然后根据类型文档调用另一个函数。除了需要进行一些清理的HTML文档之外，所有内容都非常简单，而且根据它的来源，清理会有所不同。所以我有一个想法，我可以将一个子程序的引用传递给转换函数，这样调用者就有机会修改HTML，有点像（我不在工作，所以这不是复制和粘贴）：

package Converter;
...
sub convert
{
    my ($self, $filename, $coderef) = @_;

    if ($filename =~ /html?$/i) {
        $self->_convert_html($filename, $coderef);
    }
}

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    my $html = $self->slurp($filename);
    $coderef->(\$html); #this modifies the html
    $self->save_to_file($filename, $html);
}

然后由：

调用

Converter->new->convert("./whatever.html", sub { s/<html>/<xml>/i });

我沿着这些方面尝试了几个不同的东西，但我继续得到'在替换中使用未初始化的值（s ///）'。有没有办法做我想做的事情？

由于

Answer 1

如果是我，我会避免修改标量引用并返回更改后的值：

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    my $html = $self->slurp($filename);
    $html = $coderef->( $html ); #this modifies the html
    $self->save_to_file($filename, $html);
}

但是，如果要修改sub的参数，则值得知道所有子参数都是Perl中的pass-by-reference（@_的元素别名为sub调用的参数）。所以你的转换子看起来像：

sub { $_[0] =~ s/<html>/<xml>/ }

但是，如果您真的希望在$_上运行，就像您在所需的代码示例中所做的那样，则需要使_convert_html()看起来像：

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    my $html = $self->slurp($filename);

    $coderef->() for $html;

    $self->save_to_file($filename, $html);
}

for是正确本地化$_的简便方法。你也可以这样做：

sub _convert_html
{
    my ($self, $filename, $coderef) = @_;

    local $_ = $self->slurp($filename);

    $coderef->();

    $self->save_to_file($filename, $_);
}

Answer 2

请记住，s///本身在$_上运行，但您的标量引用作为参数传递到回调子中，因此位于@_数组中。

所以你可以把你的回调子变成这样的东西：

sub { my ( $ref ) = @_; $$ref =~ s/<html>/<xml>/i }

或者，您可以利用Perl子例程参数的别名特性，并直接修改它：

sub _convert_html { 
    ...
    $coderef->( $html );
}

然后

sub { $_[0] =~ s/<html>/<xml>/i }

（这实际上会修改原始字符串，只要参数是标量变量而不是文字字符串。）

Answer 3

试试这个：

Converter->new->convert("./whatever.html", sub { ${$_[0]} =~ s/<html>/<xml>/i; });

您正在获取未初始化的值警告，因为替换未被赋予任何操作（$_在其范围内未定义）。您需要告诉它在哪里找到它的值（在@_中作为参考）。

如果你想要花哨，你可以默认使coderef在所有args上运行：

sub { map { $$_ =~ s/<html>/<xml>/i } @_ }

如何修改传递给子例程引用的标量引用？

3 个答案: