Question

我有一个整数颜色值，如 -16447153 。以及如何将其转换为ARGB？

在c＃中，他使用了颜色功能，

Color.FromArgb(buf[buf_pos])

在delphi中是否有如上所述的函数，否则如何转换？

我试过这样：

procedure TJP2RenderPreview.put_region(size : _Ckdu_coords; buf : array of Integer; offX, offY : Integer);
var
  x, y          : Integer;
  width, height : Integer;
  buf_pos       : Integer;
  RowPtr        : PRGBQuad;
begin
  width:= size.__property_get_x;
  height:= size.__property_get_y;
  buf_pos:=0;

  for y := offY to offY + height - 1  do
  begin
    RowPtr:= formMain.imgPreview.Bitmap.ScanLine[y];
    Inc(RowPtr, offX);
    for x := 0 to width - 1  do
    begin
      RowPtr.rgbReserved:= (buf[buf_pos] div $1000000);
      RowPtr.rgbRed:= ((buf[buf_pos] mod $1000000) div $10000);
      RowPtr.rgbGreen:= ((buf[buf_pos] mod $10000) div $100);
      RowPtr.rgbBlue:= (buf[buf_pos] mod $100);
      Inc(RowPtr);
      Inc(buf_pos);
    end;
  end;

  formMain.imgPreview.Refresh;
  formMain.imgPreview.Update;
end;

但事实并非如此，似乎是灰色的：/

Answer 1

您似乎已将您的频道混淆了。当您说它是ARGB时，您将输入视为RGBA。无论如何，使用div和mod的代码都是无效的。按位移位是惯用的方式。

对于ARGB输入，您可以这样做：

procedure ARGBtoColorChannels(ARGB: DWORD; out A, R, G, B: Byte);
begin
  A := Byte(ARGB);
  R := Byte(ARGB shr 8);
  G := Byte(ARGB shr 16);
  B := Byte(ARGB shr 24);
end;

或者如果你从RGBA开始，那么它就是这样的：

procedure RGBAtoColorChannels(RGBA: DWORD; out A, R, G, B: Byte);
begin
  R := Byte(RGBA);
  G := Byte(RGBA shr 8);
  B := Byte(RGBA shr 16);
  A := Byte(RGBA shr 24);
end;

这些是小端版本，因为在撰写本文时Delphi仅针对小端机器。

如果您正在寻找将ARGB转换为RGBA的功能，那么您可以这样做：

function ARGBtoRGBA(ARGB: DWORD): DWORD;
var
  A, R, G, B: Byte;
begin
  ARGBtoColorChannels(ARGB, A, R, G, B);
  Result := R or (G shl 8) or (B shl 16) or (A shl 24);
end;

为了完整性，反过来是：

function RGBAtoARGB(RGBA: DWORD): DWORD;
var
  A, R, G, B: Byte;
begin
  RGBAtoColorChannels(RGBA, A, R, G, B);
  Result := A or (R shl 8) or (G shl 16) or (B shl 24);
end;

为了让您知道该怎么做，您需要了解buf是什么。是ARGB还是RGBA？假设它是ARGB，似乎可能是您的问题的内容，您正试图复制到RowPtr，这似乎也是ARGB。在这种情况下，你可以像这样blit颜色：

PInteger(RowPtr)^ := buf[buf_pos];

我还强烈建议您更改buf参数的类型。这里的无符号类型更好，因为您可能需要执行按位运算。你还要通过堆栈复制整个阵列的效率非常低。对于大位图，您将遇到堆栈溢出。相反，该参数应为：

const buf: array of DWORD;

或

const buf: array of Cardinal;

使用const表示传递对数组的引用，而不是副本。

您也可以避免使用PRGBQuad并声明RowPtr为PCardinal类型，例如。

然后您可以像这样分配：

RowPtr^ := buf[buf_pos];

此时你不需要逐像素地完成它。您可以使用Move复制整个扫描线，因为这只是一个简单的blit。

for y := offY to offY + height - 1  do
begin
  RowPtr := formMain.imgPreview.Bitmap.ScanLine[y];
  Inc(RowPtr, offX);
  Move(buf[buf_pos], RowPtr^, width*SizeOf(RowPtr^));
  Inc(buf_pos, width);
end;

调用Refresh和Update似乎毫无意义。我不确定你是否也需要打电话，但如果你这样做，只需拨打Invalidate吧！

颜色到ARGB转换

1 个答案: