Question

我正在编写一个简单的.bat备份脚本，作为其中的一部分，我希望在达到设置的备份最大限制时删除最旧的备份（文件夹）。

现在我有这个：

%COUNTER%基于当前存储备份的目录中的备份文件夹数，并在脚本的前面计算。

%MAXBACKUPS%只是用户指定的数字，例如“10”，表示您只想保留最多10个版本的备份。

:: Delete the oldest backup, but only if we've exceeded the desired number of backups.
IF %COUNTER% gtr %MAXBACKUPS% (
ECHO More than %MAXBACKUPS% backups exist. Deleting oldest...
FOR /f "delims=" %%a in ('dir "..\Backup\*" /t:c /a:d /o:-d /b') do rd /s /q "..\Backup\%%a"
::Increment the counter down since we've just removed a backup folder.
SET /a COUNTER=%COUNTER%-1
)

我希望这个脚本只删除..\Backup文件夹中最旧的文件夹，但是当它达到备份限制时，它似乎会删除它找到的每个文件夹，这显然不是所希望的行为。

Answer 1

你太近了！： - ）

您需要做的就是按日期降序排序时跳过第一个%MAXBACKUPS%条目。您甚至不需要COUNTER变量。

:: Preserve only the %MAXBACKUPS% most recent backups.
set "delMsg="
for /f "skip=%MAXBACKUPS% delims=" %%a in (
  'dir "..\Backup\*" /t:c /a:d /o:-d /b'
) do (
  if not defined delMsg (
    set delMsg=1
    echo More than %MAXBACKUPS% found - only the %MAXBACKUPS% most recent folders will be preserved.
  )
  rd /s /q "..\Backup\%%a"
)

Answer 2

根据您的脚本执行此操作的简单方法：

FOR /f "delims=" %%a in ('dir "..\Backup\*" /t:c /a:d /o:-d /b') do set lastfolder=%%a

rd /s /q "..\Backup\%lastfolder%"

所以你仍然循环遍历每个文件夹，按年龄排序，但你覆盖％lastfolder％，所以最后它只包含最旧文件夹的名称。

然后删除该文件夹。

Answer 3

这是我最终使用的最后一段代码：

:: Preserve only the %MAXBACKUPS% most recent backups.
FOR /f "skip=%MAXBACKUPS% delims=" %%a in (
'dir "..\Backup\*" /t:c /a:d /o:-d /b'
) do (
ECHO More than %MAXBACKUPS% backups found--Deleting "%%a".
ECHO.
rd /s /q "..\Backup\%%a"
)

它简化了删除消息代码，并在最终用户的命令提示符窗口中提供了有关删除了哪些文件的信息。

基于dbenham's answer.

Answer 4

FOR /f "delims=" %%a in ('dir "..\Backup\*" /t:c /a:d /o:d /b') do (
 rd /s /q "..\Backup\%%a"
 goto :break
)
:break

你可以用goto打破for循环

批处理脚本删除给定文件夹中最旧的文件夹

4 个答案: