Question

我正在尝试在Delphi 7中实现数组追加，因为标准库没有它。这是我到目前为止所做的，但当我试图获得数组的长度时，它会抱怨不兼容的类型。

procedure ArrayAppend(var GenericArray; const Element);
var
  len: Integer;
begin
  len := Length(GenericArray);
  SetLength(GenericArray, len+1);
  GenericArray[len] := Element;
end;

我正在尝试在Delphi 7中找到最通用的数组类型。

如果这是唯一的方法，我也没有问题返回修改过的数组。

Answer 1

为了说明Rob Kennedy在评论中所说的内容，这里有一个函数可以将值附加到动态数组中。但是，这是一个相当残缺的功能，因为它不支持托管类型。所以你不能拥有字符串，接口，变体或动态数组。或者实际上是包含任何托管类型的复合结构。

{$APPTYPE CONSOLE}

uses
  SysUtils,
  TypInfo;

type
  PDynArrayTypeInfo = ^TDynArrayTypeInfo;
  TDynArrayTypeInfo = packed record
    kind: Byte;
    name: Byte;
    elSize: Longint;
    elType: ^PDynArrayTypeInfo;
    varType: Integer;
  end;

function DynArraySize(a: Pointer): Integer;
asm
        TEST EAX, EAX
        JZ   @@exit
        MOV  EAX, [EAX-4]
@@exit:
end;

type
  TIntegerArray = array of Integer;

procedure AppendUnmanaged(var arr{: TArray<T>}; const Value{: T}; TypeInfo: PTypeInfo);
var
  len, elSize: Integer;
begin
  len := DynArraySize(Pointer(arr)) + 1;
  DynArraySetLength(Pointer(arr), TypeInfo, 1, @len);
  inc(PAnsiChar(TypeInfo), PDynArrayTypeInfo(TypeInfo).name);
  elSize := PDynArrayTypeInfo(TypeInfo).elSize;
  Move(Value, (PAnsiChar(Pointer(arr)) + (len-1)*elSize)^, elSize);
end;

procedure Main;
var
  arr: TIntegerArray;
  i, Value: Integer;
begin
  Value := -1;
  AppendUnmanaged(arr, Value, TypeInfo(TIntegerArray));

  Value := 666;
  AppendUnmanaged(arr, Value, TypeInfo(TIntegerArray));

  Value := 42;
  AppendUnmanaged(arr, Value, TypeInfo(TIntegerArray));

  for i := low(arr) to high(arr) do
    Writeln(arr[i]);
end;

begin
  try
    Main;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

与现代Delphi相比，你可以看到一些明显的问题，Delphi具有通用类型和数组连接。我特别想到了这些问题：

您必须为该功能提供类型信息。
您无法传递文字，因为它们无效为无类型参数。

现在，当然可以复制编译器在分配托管类型时所执行的操作。但这真的值得吗？上面的代码，特别是调用代码，真的是对类型安全替代品的改进吗？就个人而言，我不这么认为。

数组附加在delphi中

1 个答案: