Question

我使用XSLT进行一些输出格式化，我希望在输出的每N个节点周围都有一个包装元素。我已阅读xslt - adding </tr><tr> every n node?，但我的问题是源节点必须来自查找：

<xsl:for-each select="key('items-by-product', $productid)">

而不仅仅是模板匹配。我发现的所有示例都假设您想要的节点彼此相邻，并且它们只是计算兄弟姐妹。

我有一个适合我的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
  <xsl:variable name='num_per_div' select='2' />
  <xsl:variable name='productid' select='1' />
  <xsl:output method="xml" indent="yes"/>
  <xsl:key name="items-by-product" match="item" use="productid"/>
  <xsl:template match="data">
    <output>
      <xsl:for-each select="key('items-by-product', $productid)">
        <xsl:variable name='pos' select='position()' />
        <xsl:if test="position() = 1 or not((position()-1) mod $num_per_div)">
          <outer pos="{$pos}">
            <xsl:for-each select="key('items-by-product', $productid)">
              <xsl:variable name='ipos' select='position()' />
              <xsl:if test="$ipos >= $pos and $ipos &lt; $pos + $num_per_div">
                <inner>
                  <xsl:value-of select="itemid"/>
                </inner>
              </xsl:if>
            </xsl:for-each>
          </outer>
        </xsl:if>
      </xsl:for-each>      
    </output>
  </xsl:template>
</xsl:stylesheet>

带数据

<data>
  <item>
    <productid>1</productid>
    <itemid>1</itemid>
  </item>
  <item>
    <productid>1</productid>
    <itemid>2</itemid>
  </item>
  <item>
    <productid>2</productid>
    <itemid>A</itemid>
  </item>
  <item>
    <productid>1</productid>
    <itemid>3</itemid>
  </item>
  <item>
    <productid>2</productid>
    <itemid>B</itemid>
  </item>
  <item>
    <productid>1</productid>
    <itemid>4</itemid>
  </item>
</data>

产生

<?xml version="1.0" encoding="utf-8"?>
<output>
  <outer pos="1">
    <inner>1</inner>
    <inner>2</inner>
  </outer>
  <outer pos="3">
    <inner>3</inner>
    <inner>4</inner>
  </outer>
</output>

但这是循环遍历每个节点的所有节点，这让我觉得效率低下。

是否有更好的方法可以更有效地生成相同的输出？以下兄弟技术可以使用过滤器吗？

Answer 1

您可以使用带有position() mod $num_per_div的外部循环来获得每个块的一次“迭代”，然后在其中选择该块的成员，这些成员由其位置设置的整个key(...)节点： / p>

<xsl:for-each select="key('items-by-product', $productid)
                       [position() mod $num_per_div = 1]">
  <xsl:variable name="iter" select="position()" />
  <xsl:variable name="first" select="($iter - 1) * $num_per_div + 1" />
  <xsl:variable name="last" select="$iter * $num_per_div" />
  <outer pos="{$first}">
    <xsl:for-each select="key('items-by-product', $productid)
                           [position() &gt;= $first and position() &lt;= $last]">
      <inner><xsl:value-of select="itemid"/></inner>
    </xsl:for-each>
  </outer>
</xsl:for-each>

这里的关键是要记住position()函数是上下文敏感的，并且在不同的时间意味着不同的东西。在$iter变量的定义中，当前节点列表是外部for-each选择的节点，即具有返回的第一，第三，第五等项目的列表。密钥（所以position()表示块编号）。但是在 inner 的select的谓词中，每个当前节点列表 all 从key函数调用返回的节点（所以position()是被测节点在具有给定productid的所有节点的列表中的位置。

Answer 2

您可以从将感兴趣的节点复制到变量中开始;这将使他们 - 只有他们 - 兄弟姐妹。但是，在XSLT 1.0中，此类变量将包含 result-tree-fragment ，需要将其转换为 node-set 才能进一步处理：

XSLT 1.0

<?xml version="1.0" encoding="UTF-8"?> <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:exsl="http://exslt.org/common" extension-element-prefixes="exsl"> <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> <xsl:key name="items-by-product" match="item" use="productid"/> <xsl:variable name="groupSize" select="2" /> <xsl:variable name="productid" select="1" /> <xsl:variable name="my-items"> <xsl:copy-of select="key('items-by-product', $productid)"/> </xsl:variable> <xsl:template match="/"> <output> <xsl:for-each select="exsl:node-set($my-items)/item[position() mod $groupSize = 1]"> <outer pos="{position()}"> <xsl:for-each select=". | following-sibling::item[position() < $groupSize]" > <inner> <xsl:value-of select="itemid"/> </inner> </xsl:for-each> </outer> </xsl:for-each> </output> </xsl:template> </xsl:stylesheet>

XSLT每个第n个节点都有一个过滤器

2 个答案: