Question

我想在某个假设存在的情况下应用规则，而另一个假设不存在。我该如何检查这种情况？

例如：

Variable X Y : Prop.
Axiom A: X -> Y.
Axiom B: X -> Z.

Ltac more_detail :=
    match goal with
     |[H1:X,<not H2:Y>|-_]  =>
      let H' := fresh "DET" in assert Y as H'
                                   by (apply A;assumption)
     |[H1:X,<not H2:Z>|-_]  =>
      let H' := fresh "DET" in assert Z as H'
                                   by (apply B;assumption)
    end.

这样，为了这个目标：

> Goal X->True. intros.

H:X
=====
True

more_detail.会引入第二个假设DET：

H:X
DET:Y
DET0:Z
=====
True

连续调用more_detail.会失败。

但more_detail.应始终确保Y和Z都存在，即如果只有其中一个存在，则应为另一个规则运行规则：

Goal X->Y->True. intros.

H:X
H1:Y
=====
True

> more_detail.

H:X
H1:Y
DET:Z
=====
True

和

> Goal X->Z->True. intros.

H:X
H0:Z
=====
True

> more_detail.

H:X
H0:Z
DET:Y
=====
True

Answer 1

这是一种常见的Ltac模式。您可以使用fail策略来避免在某些条件匹配时执行分支：

Variable X Y Z : Prop.
Hypothesis A : X -> Y.
Hypothesis B : X -> Z.

Ltac does_not_have Z :=
  match goal with
  | _ : Z |- _ => fail 1
  | |- _ => idtac
  end.

Ltac more_detail :=
  match goal with
  | H : X |- _ =>
    first [ does_not_have Y;
            let DET := fresh "DET" in
            assert (DET := A H)
          | does_not_have Z;
            let DET := fresh "DET" in
            assert (DET := B H) ]
  end.

Goal X -> True.
intros X. more_detail. more_detail.
(* This fails *)
more_detail.
Abort.

does_not_have策略充当否定匹配：只有在上下文中不存在其参数时才会成功。以下是它的工作原理：如果上下文中存在H : Z，则第一个分支将匹配。简单地调用fail或fail 0会导致该分支失败，但会允许Ltac尝试相同match的其他分支。使用fail 1会导致当前分支和整个匹配失败。如果上下文中不存在H : Z，则第一个分支将永远不会匹配，Coq将跳过它并尝试第二个分支。由于这个分支没有做任何事情，执行将继续match之后的任何策略。

在more_detail中，first战术可用于组合does_not_have的多个调用;因为如果上下文包含相应的假设，first的每个分支都将失败，所以整个构造将具有带有负模式的match的效果。

怎么做＆＃34;否定＆＃34;在Ltac比赛？

1 个答案: