禁用表单仍允许子控件接收输入

时间：2015-02-09 11:42:25

标签： delphi delphi-xe2

我在使用delphi的最后几天遇到了很多麻烦，我试图做的很简单，在某个点阻止界面并在其他点之后启用。

但就像它听起来一样，我无法弄清楚为什么设计允许某些事情，所以要澄清：

1）创建一个项目

2）在表格中放置一个编辑和一个按钮，编辑的标签顺序必须是第一个

3）配置编辑的OnExit事件并写入：

Enabled := False;

4）配置按钮的OnClick事件并写入：

ShowMessage('this is right?');

基本上就是它，现在编译，它将在编辑时按下，按下选项卡，表格将根据我们的要求被禁用，因此相应的标签顺序下一个控件获得焦点是按钮（但我们禁用表单），现在按空格键，消息应该出现。

所以问题是：这是对的吗？对这种行为的逻辑解释是什么？

提前thx。

1 个答案:

答案 0 :(得分：10)

TButton和TEdit都是TWinControl后代 - 这意味着它们是窗口控件。创建它们时，它们将被分配自己的HWND，操作系统在有焦点时直接向它们发送消息。禁用其包含的表单会阻止主窗体接收输入消息或接收焦点，但如果已经有输入焦点，则不会禁用任何其他窗口控件。

如果这些控件没有输入焦点，则当用户输入（单击，制表键等）指示时，包含表单的责任是将输入焦点传输给它们。如果表单被禁用并且这些控件没有聚焦，那么表单将不会收到允许它传输焦点的输入消息。但是，如果将 转移到窗口控件，则所有用户输入都直接转到该控件，即使它们的父控件窗口被禁用 - 它们实际上是它们自己的独立窗口。

我不确定你观察到的行为是一个错误 - 它可能不是预期的，但它是标准行为。通常不期望禁用一个窗口也会禁用同一应用程序中的其他窗口。

问题在于有两个独立的层次结构在起作用。在VCL级别，Button是一个子控件，并具有父级（表单）。但是，在操作系统级别，两者都是单独的窗口，并且操作系统不知道（组件级别）父/子关系。这将是类似的情况：

procedure TForm1.Button1Click(Sender: TObject);
var
  form2 : TForm1;
begin
  self.Enabled := false;
  form2 := TForm1.Create(self);
  try
    form2.ShowModal;
  finally
    form2.Free;
  end;
end;

您是否真的希望form2在显示时被禁用，只是因为其TComponent所有者是Form1？当然不是。窗口控件大致相同。

Windows本身也可以具有父/子关系，但这与组件所有权（VCL父/子）分开，并且不一定以相同的方式运行。 From MSDN：

  

系统将子窗口的输入消息直接传递给   儿童窗;消息不通过父窗口传递。   唯一的例外是，如果已禁用子窗口   EnableWindow功能。在这种情况下，系统传递任何输入   将转到子窗口到父窗口的消息   代替。这允许父窗口检查输入消息   并在必要时启用子窗口。

强调我的 - 如果您禁用子窗口，则其消息将被路由到父级，以便有机会检查并对其进行操作。反之亦然 - 禁用的父母不会阻止孩子接收消息。

一个相当繁琐的解决方法可能是创建一组行为如此的TWinControl：

 TSafeButton = class(TButton)
   protected
     procedure WndProc(var Msg : TMessage); override;
 end;

 {...}

procedure TSafeButton.WndProc(var Msg : TMessage);
  function ParentForm(AControl : TWinControl) : TWinControl;
  begin
    if Assigned(AControl) and (AControl is TForm) then
      result := AControl
    else
      if Assigned(AControl.Parent) then
        result := ParentForm(AControl.Parent)
      else result := nil;
  end;
begin
  if Assigned(ParentForm(self)) and (not ParentForm(self).Enabled) then
    Msg.Result := 0
  else
    inherited;
end;

这会向上移动VCL父树，直到它找到一个表单 - 如果它找到并且表单被禁用，那么它也会拒绝对窗口控件的输入。凌乱，也许可能更有选择性（也许一些信息不应该被忽略......）但它可能是一些可行的开始。

进一步挖掘，这似乎与with the documentation：

不一致
  

一次只能有一个窗口可以接收键盘输入;那个窗口是   据说有键盘焦点。如果应用程序使用   EnableWindow函数禁用键盘焦点窗口，即窗口   除了被禁用之外，还会丢失键盘焦点。 EnableWindow   然后将键盘焦点设置为NULL，这意味着没有窗口具有焦点。   如果子窗口或其他后代窗口具有键盘焦点，   当父窗口出现时，后代窗口会失去焦点   禁用。有关更多信息，请参阅键盘输入。

这似乎不会发生，甚至明确将按钮的窗口设置为以下儿童：

 oldParent := WinAPI.Windows.SetParent(Button1.Handle, Form1.Handle);
 // here, in fact, oldParent = Form1.Handle, so parent/child HWND
 // relationship is correct by default.

多一点（对于repro） - 相同的方案Edit标签聚焦到按钮，退出处理程序启用TTimer。这里表单被禁用，但是按钮保持焦点，即使这似乎确认Form1的HWND确实是按钮的父窗口，它应该失去焦点。

procedure TForm1.Timer1Timer(Sender: TObject);
var
  h1, h2, h3 : cardinal;
begin      
  h1 := GetFocus;       // h1 = Button1.Handle 
  h2 := GetParent(h1);  // h2 = Form1.Handle
  self.Enabled := false;      
  h3 := GetFocus;       // h3 = Button1.Handle
end;

如果我们将按钮移动到面板，一切似乎都按预期工作（大部分）。面板被禁用，按钮失去焦点，但焦点移动到父窗体（WinAPI建议它应该为NULL）。

procedure TForm1.Timer1Timer(Sender: TObject);
var
  h1, h2, h3 : cardinal;
begin      
  h1 := GetFocus;       // h1 = Button1.Handle 
  h2 := GetParent(h1);  // h2 = Panel1.Handle
  Panel1.Enabled := false;      
  h3 := GetFocus;       // h3 = Form1.Handle
end;

问题的一部分似乎在这里 - 看起来顶级形式本身正在负责控制散焦。这种方式有效，除非表单本身是被禁用的表单：

procedure TWinControl.CMEnabledChanged(var Message: TMessage);
begin
  if not Enabled and (Parent <> nil) then RemoveFocus(False);
                 // ^^ False if form itself is being disabled!
  if HandleAllocated and not (csDesigning in ComponentState) then
    EnableWindow(WindowHandle, Enabled);
end;
procedure TWinControl.RemoveFocus(Removing: Boolean);
var
  Form: TCustomForm;
begin
  Form := GetParentForm(Self);
  if Form <> nil then Form.DefocusControl(Self, Removing);
end

哪里

procedure TCustomForm.DefocusControl(Control: TWinControl; Removing: Boolean);
begin
  if Removing and Control.ContainsControl(FFocusedControl) then
    FFocusedControl := Control.Parent;
  if Control.ContainsControl(FActiveControl) then SetActiveControl(nil);
end;

这部分解释了上述观察到的行为 - 焦点移动到父控件并且活动控件失去焦点。它仍然无法解释为什么“EnableWindow”无法将焦点锁定在按钮的子窗口上。这确实看起来像WinAPI问题......

相关问题
最新问题