使用Julia检查变量的大小（以字节为单位）

Question

问题：如何使用Julia检查变量的大小 ？

我尝试过的内容：在Matlab中，whos()函数提供了此信息，但在Julia中只提供了变量名称和模块。浏览Julia手册中的标准库，sizeof()看起来很有前途，但它似乎只提供规范二进制表示的大小，而不是当前变量。

Answer 1

sizeof也适用于变量

sizeof(a::Array{T,N})

返回数组大小乘以元素大小。

julia> x = [1 2 3 4]
1x4 Array{Int64,2}:
 1  2  3  4

julia> sizeof(x)
32

julia> x = Int8[1 2 3 4]
1x4 Array{Int8,2}:
 1  2  3  4

julia> sizeof(x)
4

sizeof(B::BitArray{N})

返回块;每个块是8个字节，因此最多可以表示64位

julia> x = BitArray(36);
julia> sizeof(x)
8 

julia> x = BitArray(65);
julia> sizeof(x)
16

sizeof(s::ASCIIString)和sizeof(s::UTF8String)

返回字符串中的字符数（1个字节/字符）。

julia> sizeof("hello world")
11

sizeof(s::UTF16String)和sizeof(s::UTF32String)

与上面相同，但分别有2个和4个字节/字符。

julia> x = utf32("abcd");
julia> sizeof(x)
16

相应的其他strings

sizeof(s::SubString{ASCIIString}) at string.jl:590
sizeof(s::SubString{UTF8String}) at string.jl:591
sizeof(s::RepString) at string.jl:690
sizeof(s::RevString{T<:AbstractString}) at string.jl:737
sizeof(s::RopeString) at string.jl:802
sizeof(s::AbstractString) at string.jl:71

core values

返回每个变量使用的字节数

julia> x = Int64(0);
julia> sizeof(x)
8

julia> x = Int8(0);
julia> sizeof(x)
1

julia> x = Float16(0);
julia> sizeof(x)
2

julia> x = sizeof(Float64)
8

人们会指望，但请注意朱莉娅角色是宽字符

julia> sizeof('a')
4

的getBytes

对于布局更复杂和/或不连续的情况。这是一个函数，它将迭代变量的字段（如果有的话）并返回所有sizeof结果的总和，这应该是分配的总字节数。

getBytes(x::DataType) = sizeof(x);

function getBytes(x)
   total = 0;
   fieldNames = fieldnames(typeof(x));
   if fieldNames == []
      return sizeof(x);
   else
     for fieldName in fieldNames
        total += getBytes(getfield(x,fieldName));
     end
     return total;
   end
end

使用它

创建random-ish类型的实例......

julia> type X a::Vector{Int64}; b::Date end

julia> x = X([i for i = 1:50],now())
X([1,2,3,4,5,6,7,8,9,10  …  41,42,43,44,45,46,47,48,49,50],2015-02-09)

julia> getBytes(x)
408

Answer 2

函数Base.summarysize正是提供了这一点

它还包括该结构的开销，如示例所示。

julia> struct Foo a; b end

julia> Base.summarysize(ones(10000))
80040

julia> Base.summarysize(Foo(ones(10000), 1))
80064

julia> Base.summarysize(Foo(ones(10000), Foo(ones(10, 10), 1)))
80920

但是，应注意，因为该功能未导出且可能无法证明未来

Answer 3

在 julia 1.6 中，varinfo() 显示大小：

julia> a = 1;
julia> v = ones(10000);
julia> varinfo()
  name                    size summary                      
  –––––––––––––––– ––––––––––– –––––––––––––––––––––––––––––
  Base                         Module                       
  Core                         Module                       
  InteractiveUtils 250.022 KiB Module                       
  Main                         Module                       
  ans               78.164 KiB 10000-element Vector{Float64}
  v                 78.164 KiB 10000-element Vector{Float64}
  a                    8 bytes Int64

对于特定变量，要么使用模式匹配（r"..." 是 regular expression）：

julia> varinfo(r"^v$")
  name       size summary                      
  –––– –––––––––– –––––––––––––––––––––––––––––
  v    78.164 KiB 10000-element Vector{Float64}

或将 Base.summarysize 中的 Korbinian answer 与 Base.format_bytes 结合：

julia> pretty_summarysize(x) = Base.format_bytes(Base.summarysize(x))
pretty_summarysize (generic function with 1 method)

julia> pretty_summarysize(v)
"78.164 KiB"

编辑：请注意 summarysize 有 bug，至少在 1.5.3 和 1.6.1 中。 varinfo 也受到影响。