Question

我有一个输入文件。我需要扫描第3列中第1列和第2列的值/数字，如果匹配打印$ 1和$ 2，则相应的$ 4，如下所示输出。任何帮助表示赞赏。

要匹配$ 3中的第一列，请尝试使用此代码，但它无法正常工作。逻辑是将3美元放入一个数组并扫描1美元。

awk -F ',' '{a[$3] } { if ($1 in a) {print $1":" $4 } else {print $1, "NA"}  }' 1.csv

输入

 345,1314,567,index-1
 344,1315,566,index-2
 343,1316,565,index-3
 342,1317,1316,index-4
 241,1318,563,index-5
 340,1319,562,index-6
 439,1320,561,index-7
 318,1333,337,index-8
 337,1335,559,index-9
 236,1336,558,index-10
 ,,311,index-11
 ,,1314,index-12
 ,,1333,index-13
 ,,3444,index-14
 ,,344,index-15
 ,,2008,index-16
 ,,342,index-17
 ,,1320,index-18
 ,,543,index-19
 ,,340,index-20
 ,,12233,index-21

输出

 345:#N/A
 344:index-15
 343:#N/A
 342:index-17
 241:#N/A
 340:index-20
 439:#N/A
 318:#N/A
 337:index-8
 236:#N/A
 1314:index-12
 1315:#N/A
 1316:index-4
 1317:#N/A
 1318:#N/A
 1319:#N/A
 1320:index-18
 1333:index-13
 1335:#N/A
 1336:#N/A

Answer 1

$ cat nash.awk
NR == FNR { a[$3] = $4; next }    
($1 in a) { print $1 ":" a[$1] }  
($2 in a) { print $2 ":" a[$2] }
$1 && !($1 in a) { print $1 ": #N/A"}    
$2 && !($2 in a) { print $2 ": #N/A"}

请注意，我们提供两次文本文件，因为awk脚本进行了两次传递（请参阅下面的更多说明）：

$ awk -F, -f nash.awk nash.txt nash.txt

1314:index-12
345: #N/A
344:index-15
1315: #N/A
1316:index-4
343: #N/A
342:index-17
1317: #N/A
241: #N/A
1318: #N/A
340:index-20
1319: #N/A
1320:index-18
439: #N/A
1333:index-13
318: #N/A
337:index-8
1335: #N/A
236: #N/A
1336: #N/A

说明：

NR == FNR { a[$3] = $4; next }

当NR == FNR时，我们知道我们是第一次阅读该文件。在这里，我们保存与$4对应的所有$3值。 next表示我们跳过所有进一步的命令。

($1 in a) { print $1 ":" a[$1] }

如果我们在这里，我们知道我们正在第二次阅读该文件。检查字段1是否与任何字段3匹配，如果是，则将其与上面步骤中保存的字段4一起打印。

($2 in a) { print $2 ":" a[$2] }

与上述相同，但是对于第二个字段。

$1 && !($1 in a) { print $1 ": #N/A"}

同样，如果第一个字段 not ，则打印N / A消息。

$2 && !($2 in a) { print $2 ": #N/A"}

与第二场相同的内容。

AWK在同一文件中的列之间查找（类似于vlookup）

1 个答案: