Question

我试图找出如何使用vbscript：
1 - 打开.csv文件作为.txt文件
2 - 搜索整个文本中随机定位的特定字符串 3 - 用不同的字符串替换该字符串。

我找到了一篇文章，帮助我学习如何替换.txt文档中的整行，但到目前为止还没有找到任何关于替换行中某些字符的内容。

谢谢！

以下是我目前使用的代码：

Const ForReading = 1
Const ForWriting = 2

'Setting up our objects and focusing on the text file.
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\Users\Documents\Script Practice\TextFiles-2-4-15-Folder\ReadandWrite\Textlook.txt", ForReading)


Do Until objFile.AtEndOfStream

    strLine = objFile.ReadLine


    If strLine = "Myer" Then
        strLine = "Mike"
    End If

    strContents = strContents & strLine & vbCrLf

Loop



objFile.Close


Set objFile = objFSO.OpenTextFile("C:\Users\Documents\Script Practice\TextFiles-2-4-15-Folder\ReadandWrite\Textlook.txt", ForWriting)


objFile.Write(strContents)
objFile.Close

它引用的文本文件说：
Ken Myer
Fabrikam

皮拉尔·阿克曼（Pilar Ackerman） Wingtip玩具

杰夫干草 Fabrikam

艾伦亚当斯 Northwind Traders

迈尔

（文本文件结束）。基本上，我已经获得了成功更改＆＃34; Myer＆＃34;这是与＃34; Mike＆＃34;有关的。我正在努力改变的是＃Myer＆＃34; Myer＆＃34;在迈克＆＃34;的第一行。希望这有助于澄清一些事情......我对此非常陌生，因此不确定我应该使用哪种语言来描述问题。

Answer 1

对.ReadAll（）获取的文件内容使用替换，并将结果写回。在代码中：

Option Explicit

Dim goFS  : Set goFS  = Createobject("Scripting.FileSystemObject")
Dim goWAU : Set goWAU = WScript.Arguments.Unnamed

WScript.Quit main()

Function main()
  main = 1 ' assume error
  If 3 = goWAU.Count Then
     If goFS.FileExists(goWAU(0)) Then
        Dim s : s = goFS.OpenTextFile(goWAU(0)).ReadAll()
        If 0 < Instr(s, goWAU(1)) Then
           goFS.CreateTextFile(goWAU(0)).Write Replace(s, goWAU(1), goWAU(2))
           WScript.Echo "done"
           main = 0
        Else
           WScript.Echo goWAU(1), "not found"
        End If
     Else
        WScript.Echo goWAU(0), "does not exist"
     End If
  Else
     WScript.Echo "need 3 args: fspec, find, replacement"
  End If
End Function

输出：

copy con 28350055.csv
1,2,3
4,5,6
^Z

cscript 28350055.vbs 28350055.csv 5 4711
done

type 28350055.csv
1,2,3
4,4711,6

cscript 28350055.vbs 28350055.csv 5 4711
5 not found

cscript 28350055.vbs 28350055.cs 5 4711
28350055.cs does not exist

使用该演示确定解决现实世界问题所需的内容。

Answer 2

我也是新手，所以我没有在代码中得到其他答案的作用，但我在最后一个关于“Replace”的答案中发现并在您的代码中使用以完成您需要的操作，结果是这样的：

Const ForReading = 1
Const ForWriting = 2

'Setting up our objects and focusing on the text file.
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\Users\Documents\Script Practice\TextFiles-2-4-15-Folder\ReadandWrite\Textlook.txt", ForReading)


Do Until objFile.AtEndOfStream

    strLine = objFile.ReadLine


    strLine = Replace(strLine,"Myer","Mike")

    ' If strLine = "Myer" Then
        ' strLine = "Mike"
    ' End If

    strContents = strContents & strLine & vbCrLf

Loop



objFile.Close


Set objFile = objFSO.OpenTextFile("F:\BIBLIOTECAS\Archivos\TEST.txt", ForWriting)


objFile.Write(strContents)
objFile.Close

使用VBscript在.text文件中查找和替换字符串

2 个答案: